Remember

How well can you remember a 7-digit telephone number? Look at such a number, turn away and whistle a tune, and then try to recall the number.

This game program gives you such numbers to REMEMBER. The routine is also third in a series that compares the use of a joystick with the use of INKEY$ to produce motion in the player’s piece. Although this routine has been fabricated to allow either method used. A joystick might be preferred by most player’s in this game because of it’s vertical motion requirement.

If you agree, you may want to delete reference to INKEY$ in lines 330 and 340. The program will run a little faster if the computer is relieved of having to do an unnecessary work in the GOTO loop between lines 320 and 400.

  5 REM ** REMEMBER **
              ***
      Spectrum or T/S 2068
              by
          Warren Fricke
  8 GO SUB 500
 10 REM  [illegible]
 15 INPUT z$: CLS
 20 PRINT AT 2,5;"0 1 2 3 4 5 6 7 8 9"
 25 POKE 23658,8
 30 FOR n=2 TO 17
 40 PRINT AT n,4;"▒";AT n,24;"▒"
 50 NEXT n
 60 FOR n=4 TO 24
 70 PRINT AT 1,n;"▒";AT 18,n;"▒"
 80 NEXT n
 90 REM  [illegible]
100 LET b$="": RANDOMIZE
110 FOR L=4 TO 16 STEP 2
120 DIM a$(19)
130 LET a=INT (19*RND+1)
140 IF a/2=INT (a/2) THEN GO TO 130
150 LET a$(a)="©"
160 LET b$=b$+STR$ ((a-1)/2)
170 PRINT AT L,5; INK 4;a$
180 FOR c=6 TO 22 STEP 2
190 PRINT AT L,c; INK 1;"▒"
200 NEXT c: NEXT L
210 PRINT AT 21,0;"The above contains your number."
220 REM  [illegible]
230 INPUT z$
240 LET AA=22661
250 FOR n=0 TO 12 STEP 2
260 FOR m=0 TO 18 STEP 2
270 POKE (AA+m+32*n),36
280 NEXT m: NEXT n
285 PRINT AT 21,0;"The number is now hidden.      "
290 REM  [illegible]
300 INPUT z$
310 LET L=3: LET C=14: LET s=0
315 POKE 23673,0: POKE 23672,0
320 LET LL=L: LET CC=C
330 LET C=C+(INKEY$="M")+( STICK (1,1)=8)-(INKEY$="Z")-( STICK (1,1)=4)
340 LET L=L+(INKEY$="V")+( STICK (1,1)=2)
350 IF POINT (8*C,8*(21-L))=1 THEN BEEP .1,-10: LET L=LL: LET C=CC: GO TO 330
360 IF POINT (8*C+2,8*(21-L))=1 THEN BEEP .05,20: LET s=s+1
370 PRINT AT L,C; INK 2;"#"
380 LET T=PEEK 23672+256*PEEK 23673
385 IF T>=30*60 THEN GO TO 405
390 PRINT AT LL,CC; INK 2;"+" AND (LL<>L OR CC<>C)
395 IF L=17 THEN GO TO 410
400 GO TO 320
405 PRINT AT 8,26;"YOU";AT 9,26;"RAN";AT 10,26;"OUT";AT 11,27;"OF";AT 12,26;"TIME"
410 PRINT AT 20,0;"The number was ";b$
415 PRINT AT 21,0;"   You remembered ";s;" digits."
420 PRINT #1;"Press ENTER "; FLASH 1;"TWICE"; FLASH 0;" to start a new   game."
425 FOR n=1 TO 100: NEXT n
430 PAUSE 0: GO TO 15
500 REM  [illegible]
505 PRINT "You will get a random number  7 digits long.  It will be made upof copyright symbols in the      notches of the 7 BLUE lines.  Itreads from top to bottom."
510 PRINT ,,"Your piece ,#, starts at the topcenter.  The object is to move  it to the bottom, thru the       correctly numbered notches,      quickly, as you only get 30 sec."
515 PRINT ,,"You move the piece left by the  Z-key, right by the M-key, and  down by the V-key, or use a JOY STICK in the left port."
525 PRINT ,,"When you start, the number marksbecome hidden.  You must                    "; FLASH 1;" REMEMBER "; FLASH 0;" them."
530 PRINT ,,"Press ENTER for each, next step."
540 RETURN