John Filley of Nashville, TN, sent us a new Big Characters program, saying “Big Characters in the Dec. 80 issue had the serious limit of handling only 2 lines of 4 characters each…a 4x display should be more useful.” We agreed, and liked his approach. Our technical consultant, using John’s method to read 2 rows and 2 columns of the ROM image at once, produced this improved program.
(This exchange shows SYNTAX’s power to help you get more from your machine. User interactions produce better software.)
The REM statement creates a subset of the graphics characters in a special order and in known RAM addresses, making it easier to build large characters. The space and 15 solid graphics form all 4x characters. They are ordered so the sum of 16427 and the weights of blackened elements will equal the RAM address of the character code. Putting the REM statement first fixes the address of the space following REM at 16427.
On a 1K machine, this program prints up to 5 lines with 34 total characters, including internal spaces. With 2K or 16K RAM, it should print 5 8-character lines and a 6th line with the bottom squares cut off, giving a 5/110 error when you run out of room.
To first enter the program, type it as shown, then RUN (NL). Enter the numbers shown below, hitting (NL) between each. After you enter all 16 numbers, the string prompt appears. Type (NL) and then quickly (BREAK) to end the RUN. Get the listing back up. Delete lines 6-9. Line 2 now says 2 REM [graphics characters; see figure]. Save this version on tape.

Hit RUN (NL), then enter up to 8 characters for each prompt. It will ignore characters over 8 in one line.
2 REM ABCDEFGHIJKLMNOP
5 DIM C(7)
6 FOR X=0 TO 15
7 INPUT E
8 POKE 16427+X,E
9 NEXT X
10 INPUT A$
20 FOR X=0 TO 7
30 LET C(X)=CODE(A$)
35 IF C(X)=1 THEN GO TO 57
40 LET A$=TL$(A$)
50 NEXT X
57 LET E=X-1
60 LET L=1
70 FOR X=0 TO E
80 LET Q=C(X)*8+3583+L
85 LET R=PEEK(Q+1)
90 LET Q=PEEK(Q)
95 LET B=128
97 LET B2=B/2
110 PRINT CHR$(PEEK(16427+Q AND B)/B+4*(Q AND B2)/B2+2*(R AND B)/B+8*(R AND B2)/B2));
170 LET B=B/4
175 IF B>0 THEN GO TO 97
250 NEXT X
255 LET L=L+2
257 PRINT
260 GO TO 10-60*(L<9)
Syntactic Sum=-32591
[Editor’s note: the printed Syntactic Sum matches line 110 with one more opening parenthesis, PEEK(16427+(Q AND B)/B…, so the tested program probably read that way.]
Enter these 16 numbers in this order when you first type in the program, hitting (NL) after each:
0 4 6 2 5 131 8 135 7 136 3 133 130 134 132 128
Media
Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.