This “souped-up” version of my SYNCWARS game runs in SLOW mode (no screen flashes or jitter) and shows more spectacular displays. Otherwise, the program plays just as the 2K version, published in SQ Vol. 2 No. 1. This version uses about 6K of memory, so you need a RAM pack.
First, enter the loader program of Listing 1. Check to see that it is exactly as listed, RUN the loader and input the decimal listing shown after listing 1. Syntactic Sum now gives 18889, and the top 5 program lines should look just like lines 1-5 of listing 2, the game program. Next enter lines 10-1590 of listing 2, replacing the MC loader.
To SAVE the program to tape, enter RUN 180. Line 180 shortens SAVE/LOAD time by compressing the display file. To play after you SAVE–BREAK, POKE 16389,128 and RUN. When LOADing, this byte will already be set correctly.
Do not make any changes in lines 1-5, doing so will result in a crash. You can employ this trick to discourage people from removing your byline from programs; sandwich title and byline REMs between MC routines (1, 3, & 5). Pulling line 2 or 4 will mess up the program.
Line 1 (16514) contains a MC screen reverse routine; POKEing the 5th byte (16518) with N+1 reverses the first N lines.
Line 3 (16556) fills the ZX/TS screen fast; the fifth byte (16560) again equals one plus the number of lines to fill; byte 12 (16571) sets the fill character. POKE 16571,0 (space) to create a “clear screen” faster than CLS, and use byte five to control how many lines of the screen you clear. I’m sure you can think of other uses.
Line 5 (16597) directs the computer to a wrong character-table start address; if byte 2 isn’t 30, the screen turns to garbage. This creates the spectacular flash when you hit a zapper (key).
All 3 machine code routines are fully relocatable.
Line 210 graphics are:inv sp, inv “:”, inv “.”, inv “*”, gr “A”, “*”, “.” . The remaining graphics should be quite apparent.
Lines 650 and 750 set how much time you have to zap each invader; it gets shorter as you go along.
You try to destroy 10 invader pairs as they appear on screen. To shoot, you must depress the key corresponding to invader position. For example, press “1” if the invader is in the upper left corner, “enter” if it’s all the way to the right a little below center, and so on. SHIFT and BREAK are unused.
You score when you hit the second of each pair of invaders; the first (“Syncloid robot”) generates an “invisibility field” that hides the actual invader (“Synclon”, the one you get points for.) If you miss the robot, the field disturbance is enough to tingle the Synclon’s antennae, giving away his position; so if you’re fast you can nail him even with the field still in place. Perfect score merits a special (and rather patriotic) display.
Have fun!!
LISTING 1 (LOADER)
1 REM 12345678901234567890
2 REM SYNCWARS16
3 REM 1234567890123456789
4 REM F.NACHBAUR
5 REM 12345
80 FOR A=16514 TO 16601
90 IF A=16534 THEN LET A=16556
100 IF A=16575 THEN LET A=16597
110 INPUT B
120 POKE A,B
130 PRINT (STR$ (B+1000))(2 TO 4);":";
140 NEXT A
SYNTACTIC SUM: 16760, 8K ROM
DECIMAL LISTING–READ LEFT TO RIGHT
42 12 64 6 25 126 254 118 32 4 5 200 24 3 198 128 119 35 24 241 42 12 64 6 24 126 254 118 32 4 5 200 24 2 54 27 35 24 242 62 30 237 71 201
LISTING 2
1 REM E£RND[illegible];COS /[illegible]LEN [illegible]?7/ L ET
2 REM SYNCWARS16
3 REM E£RND[illegible]/COS /[illegible]0.7/ PAUSE
4 REM F.NACHBAUR
5 REM Y2 GOSUB ?TAN
10 GOTO 200
20 REM CLEAR SCREEN
30 POKE 16571,0
40 LET M=USR 16556
50 POKE 16571,27
60 RETURN
70 REM FLASH
80 POKE 16598,64
90 LET M=USR 16597
100 POKE 16598,PI
110 LET M=USR 16597
120 POKE 16598,22
130 LET M=USR 16597
140 POKE 16598,30
150 LET M=USR 16597
160 RETURN
180 POKE 16389,76
182 CLS
185 FAST
190 SAVE "SYNCWARS16"
197 CLS
200 SLOW
210 LET A$=" :.*▒*."
220 POKE 16418,0
230 FOR C=1 TO LEN A$
240 POKE 16571,CODE A$(C)
260 LET M=USR 16556
265 GOSUB 70
270 NEXT C
280 LET A$="1234567890QWERTYUIOPASDFGHJKL"+CHR$ 118+"ZXCVBNM."
290 LET E=3
300 LET G=28
310 LET I=18
320 LET K=16
330 GOSUB 1050
340 GOSUB 1260
350 GOSUB 70
360 GOSUB 1070
370 GOSUB 1260
380 GOSUB 70
390 GOSUB 1140
400 GOSUB 1260
410 POKE 16518,25
420 GOSUB 1390
430 PRINT AT 2,11;"SYNCWARS";AT 11,11;"BY F.NACHBAUR"
440 GOSUB 1260
450 GOSUB 1260
460 PRINT AT 0,2;"YOUR COMPUTER IS BEING INVADEDBY 10 DREAD SYNCLONS AND THEIR ""INVISIBILITY FIELD"" ROBOTS, THESYNCLOIDS."
470 LET G=10
480 LET I=3
490 GOSUB 1050
500 GOSUB 1100
510 PRINT TAB 5;"SYNCLOID SYNCLON",,,
520 PRINT " AT FIRST ONLY THE SYNCLOID ROBOT APPEARS; YOU MUST DESTROY IT TO MAKE ENEMY SYNCLON VISIBLE(BY PRESSING KEY CORRESPONDING TO ITS POSITION), AND THEN VAP- ORIZE THE SYNCLON TO SCORE. IF YOU MISS THE ROBOT, BUT HIT THE (HIDDEN) SYNCLON, YOUR SHOT IS STILL VALID."
530 PRINT AT 22,0;" PRESS P"
540 PRINT " TO START."
550 IF INKEY$="P" THEN GOTO 570
555 IF INKEY$="A" THEN GOTO 1430
560 GOTO 550
570 LET F=0
575 CLS
580 FOR C=1 TO 10
590 GOSUB 20
600 FOR A=1 TO RND*40
610 NEXT A
620 GOSUB 1160
630 LET M=USR 16556
640 GOSUB 1050
650 FOR A=1 TO 15-C/2
660 LET D$=INKEY$
670 IF D$="" THEN GOTO 720
680 GOSUB 70
690 IF D$=A$(H+1) THEN GOTO 830
700 IF D$<>A$(D+1) THEN GOTO 920
710 GOTO 740
720 NEXT A
730 GOTO 880
740 GOSUB 1070
750 FOR A=1 TO 10-C/3
760 LET D$=INKEY$
770 IF D$="" THEN GOTO 810
780 GOSUB 70
790 IF D$<>A$(H+1) THEN GOTO 920
800 GOTO 830
810 NEXT A
820 GOTO 880
830 GOSUB 1140
840 LET F=F+1
850 PRINT AT 23,0;"SCORE=";F
860 GOSUB 1260
870 GOTO 1000
880 GOSUB 20
890 PRINT AT 10,10;"TOO SLOW"
900 GOSUB 1260
910 GOTO 1000
920 PRINT AT I+1,K;">[illegible]<"
930 FOR A=1 TO 5
940 LET D$=INKEY$
950 IF D$="" THEN GOTO 990
960 GOSUB 80
970 IF D$=A$(H+1) THEN GOTO 830
980 GOTO 1000
990 NEXT A
1000 NEXT C
1010 GOSUB 1380
1020 GOSUB 1260
1030 IF F=10 THEN GOSUB 1290
1035 PRINT AT 20,2;"PRESS A TO STOP"
1040 GOTO 530
1050 PRINT AT E+1,G;"> <";TAB G;"▛█▜";TAB G;"█▀█";TAB G;"▟█▙";TAB G;"▛ ▜"
1060 RETURN
1070 GOSUB 1120
1080 GOSUB 20
1090 GOSUB 1120
1100 PRINT AT I+1,K;"> <";TAB K;"▛█▜";TAB K;"[illegible]";TAB K;"[illegible]";TAB K;"[illegible]"
1110 RETURN
1120 PRINT AT E+1,G;"/ ";TAB G; "< <";TAB G;"[illegible]";TAB G;"[illegible]";TA B G;"[illegible]"
1130 RETURN
1140 PRINT AT I+1,K;"GOT";TAB K;" [illegible]*[illegible] ";TAB K;"***";TAB K;"[illegible]*[illegible]";TA B K;"[illegible]"
1150 RETURN
1160 LET D=INT (RND*38)
1170 LET E=INT (D/10)
1180 LET G=(D-10*E)*3+E
1190 LET E=E*6-1
1200 LET H=INT (RND*38)
1210 IF H=D THEN GOTO 1200
1220 LET I=INT (H/10)
1230 LET K=(H-10*I)*3+I
1240 LET I=I*6-1
1250 RETURN
1260 FOR A=1 TO 15
1270 NEXT A
1280 RETURN
1290 LET S$="**************"
1295 FOR C=1 TO 2
1297 IF C=2 THEN LET S$=" "
1300 FOR D=1 TO 24
1310 POKE 16518,D
1320 LET M=USR 16514
1330 IF D=18 THEN PRINT AT D,8;"***TOP SCORE***"
1340 IF D=17 OR D=19 THEN PRINT AT D,8;"================"
1345 IF D>15 THEN PRINT AT D-16,0;S$
1350 NEXT D
1360 NEXT C
1365 PRINT AT 1,0;S$,,,S$,,,S$ ,,,S$,,,S$
1370 RETURN
1380 PRINT AT 12,8;" END OF GAM E ",,"FINAL SCORE=";F;" OUT O F 10"
1390 FOR A=1 TO 6
1400 LET M=USR 16514
1410 NEXT A
1420 RETURN
1430 CLS
1440 IF F=10 THEN GOTO 1520
1450 PRINT AT 8,5;"SORRY--",," THE SYNCLONS YOU MISSED GOT INTOYOUR COMPUTER. YOU[illegible]RE IN TROUBLE NOW."
1455 FOR A=1 TO 100
1460 IF A>70 THEN PRINT AT 18,10;"[illegible]";TAB 10;"[illegible]**ALERT* *[illegible]";TAB 10;"[illegible]";AT 18,1 0;"[illegible]";TAB 10;"**ALERT **";TAB 10;"[illegible]"
1462 IF A>80 THEN LET M=USR 16514
1465 NEXT A
1470 FOR A=1 TO 29
1480 POKE 16598,A
1490 LET M=USR VAL "16597"
1500 NEXT A
1510 GOTO 1530
1520 PRINT AT 8,5;"**CONGRATULATIONS**",,,"YOU[illegible]RE A HERO.",,,,"T HE SYNCLONS GAVE UP AND WENT HOME.",,,,"REPORT TO LOUNGE FOR R AND R."
1530 FOR A=1 TO 100
1540 IF INKEY$<>"" THEN GOTO 1560
1550 NEXT A
1560 CLS
1570 POKE 16598,30
1580 LET M=USR 16597
1590 PRINT AT 11,15;"END"
SYNTACTIC SUM: 62584, 8K ROM


Media
Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.