Teach Kids to Count with the ZX81

Some education theorists suggest that learning to count and read is enhanced if you create a large, sharp image in a child’s mind. This image should be easily recognized and repeated often.

Rapidly moving TV pictures get credit (and blame) for generating very powerful attention-grabbing images that anyone watching learns quickly. With your ZX81 and some intelligent program design, your TV can provide sharp graphic images of concepts you want to teach.

I wrote this program, COUNT, to help my three-year-old son learn to equate a group of objects with a number. The game draws a random number of objects on the screen and asks, “How many?” If he answers correctly, the computer tells him he’s right and draws another set. If he’s wrong, the computer asks for another answer.

Since my son can barely count much less read, written text is kept to a minimum. To keep things interesting, the program generates several shapes that occur randomly.

COUNT fits in a 1K machine, with a little extra room if you want a fancier win display. Once you enter the listing and save it, just tell your child to push R for RUN. The game repeats until you pull the plug.

---

To enter COUNT, use this guide. All keys are in graphics mode (press shift 9 first).–AZ

line 100   shift Y shift T
     105   shift T shift Y
     200   shift 8 shift G shift 5
     205   shift 8 shift F shift 5
     300   shift R shift E
     305   shift Q shift W
     400   shift W shift W shift 5
     405   shift E shift E shift 5
     500   shift W shift T
     505   shift E shift Y

The words in reverse in lines 45 and 55 are WRONG and RIGHT with asterisks.

   1 LET A=INT (RND*10)+1
   5 GOTO 100*(INT (RND*5)+1)
   7 FOR X=0 TO A-1
  10 PRINT AT 9,X*3+1;A$
  15 PRINT AT 10,X*3+1;B$
  20 NEXT X
  25 PRINT AT 0,0;"HOW MANY?"
  30 INPUT D$
  35 IF CODE D$>37 OR CODE D$<28 THEN GOTO 45
  40 IF VAL D$=A THEN GOTO 55
  45 PRINT D$;"*WRONG*"
  50 GOTO 30
  55 PRINT AT 20,6;"**** RIGHT ****"
  60 PAUSE 100
  65 CLS
  70 GOTO 1
 100 LET A$="▚▞"
 105 LET B$="▞▚"
 110 GOTO 7
 200 LET A$="▐▓▌"
 205 LET B$="▐▓▌"
 210 GOTO 7
 300 LET A$="▜▛"
 305 LET B$="▟▙"
 310 GOTO 7
 400 LET A$="▙▙▌"
 405 LET B$="▛▛▌"
 410 GOTO 7
 500 LET A$="▙▞"
 505 LET B$="▛▚"
 510 GOTO 7
SYNTACTIC SUM: 35437, 8K