Run down innocent pedestrians with your race car. Cute little tombstones mark the scene of their demise.
DEATH RACE from Games for Your Timex-Sinclair 2000, p.63.
Appears on
Capital Area Timex Sinclair User Group’s Library Tape.
Library tape of the Indiana Sinclair Timex User’s Group.
Related Content
Gallery
Source Code
10 REM DEATH RACE from Games for Your Timex-Sinclair 2000, p.63
20 GO SUB 9000: LET hi=0
30 GO SUB 8000
40 GO SUB 7000
50 PRINT AT v,h;" "
51 IF INKEY$<"5" OR INKEY$>"8" THEN GO TO 55
53 LET a$=INKEY$
55 LET v1=v: LET h1=h
60 LET v=v+(a$="6")-(a$="7")
70 LET h=h+(a$="8")-(a$="5")
80 IF SCREEN$ (v,h)="" THEN GO TO 1000
90 IF SCREEN$ (v,h)="_" THEN LET v=v1: LET h=h1: LET a$="": GO TO 55
100 PRINT AT V,H; INK 3;C$
105 LET d$=c$
110 LET c$=("\a" AND a$="7")+("\b" AND a$="8")+("\c" AND a$="6")+("\d" AND a$="5")
120 IF c$="" THEN LET c$=d$
125 PRINT AT 21,16;"TIME ";INT ti;" ": LET ti=ti-.2: IF ti<0 THEN GO TO 2000
130 BEEP .008,sc
140 PRINT AT j,k;" "
150 LET j1=j: LET k1=k
160 LET j=j+INT (RND*3)-1: LET k=k+INT (RND*3)-1
170 IF SCREEN$ (j,k)="_" THEN LET j=j1: LET k=k1: GO TO 150
175 IF SCREEN$ (j,k)="" THEN GO TO 1000
180 PRINT AT j,k; INK 5;"\f"
200 GO TO 50
1000 PRINT AT j,k;"\e"
1010 FOR a=1 TO 3
1020 LET sc=sc+1
1030 PRINT AT 21,0;"SCORE ";sc
1040 BEEP .7,sc
1050 NEXT a
1060 LET j=4: LET k=20: LET v=10: LET k=16: GO TO 40
2000 PRINT AT 21,26; PAPER 1;"TIME 0": BEEP 2,-10: CLS
2010 PRINT AT 2,12; PAPER 2;"GAME OVER"
2020 PRINT AT 5,10; PAPER 2;"YOU SCORED ";sc
2030 IF sc>hi THEN LET hi=sc
2040 PRINT AT 18,6; PAPER 6;"HIGHEST SCORE TODAY ";hi
2050 INPUT PAPER 1;"PRESS "; PAPER 2;"ENTER"; PAPER 1;" TO PLAY AGAIN"; LINE a$: GO TO 30
7000 CLS : PRINT INVERSE 1; INK 6;"________________________________"
7010 FOR a=1 TO 19
7020 PRINT INVERSE 1; INK 6;"_";AT a,31;"_"
7030 NEXT a
7040 PRINT INVERSE 1; INK 6;"________________________________"
7050 PRINT AT 21,0;"SCORE ";sc
7060 RETURN
8000 BORDER 0: PAPER 0: INK 9: CLS
8010 LET v=10: LET h=16
8020 LET j=4: LET k=20
8030 LET sc=0: LET ti=60
8040 LET c$="\a"
8050 LET a$=""
8990 RETURN
9000 FOR a=USR "a" TO USR "f"+7
9010 READ user: POKE a,user
9020 NEXT a: RETURN
9030 DATA 60,153,255,153,24,189,255,189
9040 DATA 238,68,229,255,255,229,68,238
9050 DATA 189,255,189,24,153,255,153,60
9060 DATA 119,34,167,255,255,167,34,119
9070 DATA 56,124,238,198,238,238,254,254
9080 DATA 56,56,16,124,16,16,40,68
9500 REM a b c d e f
9510 REM \a \b \c \d \e \f
9998 SAVE "Race" LINE 1: BEEP .2,15
9999 VERIFY ""