Digital Clock (QL)

Date: 1989
Type: Diskette
Platform(s): QL
Tags: Clock

A giant digital alarm clock that fills the QL screen with block digits drawn by BLOCK. Hold F1 to set the time and F2 to set the alarm time (HH:MM); the alarm buzzes while that time is shown, or CTRL and SPACE stop it (then RUN the clock again).

By Yves Gagnon (24/01/87), translated by Louis Laferriere, reprinted from the S I N newsletter, issue #18, October 1987. Line 1210 sets the date to 12 March 1989 when you set the time; if your QL has a real-time clock, edit or remove that line.

Published in Sinc-Link May-June 1989 (Digital Alarm Clock for QLers).

Related Articles

The following is a program from the SIN newsletter to provide a gigantic digital alarm clock.

Source Code

100 REMark >>>>>>>>>>>>>>>><<<><<<<<<<<<<<<<<
110 REMark >>>> from S I N   newsletter <<<<<
115 REMark <>     Issue #18 October 1987    <>
116 REMark <>   by Yves Gagnon 24/01/87     <>
117 REMark <> translation Louis Laferriere <>
118 REMark <>  time and alarm can be set    <>
119 REMark <>     by pressing F1 or F2      <>
120 REMark <<<<<<<<<<<<<<<<<<>>>>>>>>>>>>>>>>>>
130 :
140 :
150 DEFine PROCedure init
160 MODE 4
170 WINDOW 512,256,0,0
180 PAPER 0
190 CLS
200 CSIZE 1,1
210 PRINT'  DIGITAL CLOCK'
220 CSIZE 0,0
230 END DEFine init
240 :
250 DEFine PROCedure E1(x,y)
260 BLOCK 100,100,x,y,0
270 BLOCK 20,100,x+80,y,7
280 END DEFine E1
290 :
300 DEFine PROCedure E2(x,y)
310 BLOCK 100,100,x,y,0
320 BLOCK 100,20,x,y,7
330 BLOCK 20,20,x+80,y+20,7
340 BLOCK 100,20,x,y+40,7
350 BLOCK 20,20,x,y+60,7
360 BLOCK 100,20,x,y+80,7
370 END DEFine E2
380 :
390 DEFine PROCedure E3(x,y)
400 BLOCK 100,100,x,y,0
410 BLOCK 100,20,x,y,7
420 BLOCK 20,60,x+80,y+20,7
430 BLOCK 100,20,x,y+80,7
440 BLOCK 80,20,x,y+40,7
450 END DEFine E3
460 :
470 DEFine PROCedure E4(x,y)
480 BLOCK 100,100,x,y,0
490 BLOCK 20,60,x,y,7
500 BLOCK 20,100,x+80,y,7
510 BLOCK 60,20,x+20,y+40,7
520 END DEFine E4
530 :
540 DEFine PROCedure E5(x,y)
550 BLOCK 100,100,x,y,0
560 BLOCK 100,20,x,y,7
570 BLOCK 20,20,x,y+20,7
580 BLOCK 100,20,x,y+40,7
590 BLOCK 20,20,x+80,y+60,7
600 BLOCK 100,20,x,y+80,7
610 END DEFine E5
620 :
630 DEFine PROCedure E6(x,y)
640 BLOCK 100,100,x,y,0
650 BLOCK 100,20,x,y,7
660 BLOCK 20,80,x,y+20,7
670 BLOCK 80,20,x+20,y+80,7
680 BLOCK 20,40,x+80,y+40,7
690 BLOCK 60,20,x+20,y+40,7
700 END DEFine E6
710 :
720 DEFine PROCedure E7(x,y)
730 BLOCK 100,100,x,y,0
740 BLOCK 100,20,x,y,7
750 BLOCK 20,80,x+80,y+20,7
760 END DEFine E7
770 :
780 DEFine PROCedure E8(x,y)
790 BLOCK 100,100,x,y,0
800 BLOCK 100,20,x,y,7
810 BLOCK 100,20,x,y+40,7
820 BLOCK 100,20,x,y+80,7
830 BLOCK 20,100,x,y,7
840 BLOCK 20,100,x+80,y,7
850 END DEFine E8
860 :
870 DEFine PROCedure E9(x,y)
880 BLOCK 100,100,x,y,0
890 BLOCK 100,20,x,y,7
900 BLOCK 100,20,x,y+40,7
910 BLOCK 100,20,x,y+80,7
920 BLOCK 20,100,x+80,y,7
930 BLOCK 20,60,x,y,7
940 END DEFine E9
950 :
960 DEFine PROCedure E0(x,y)
970 BLOCK 100,100,x,y,0
980 BLOCK 100,20,x,y,7
990 BLOCK 20,100,x,y,7
1000 BLOCK 20,100,x+80,y,7
1010 BLOCK 100,20,x,y+80,7
1020 END DEFine E0
1030 :
1040 DEFine PROCedure EE(x,y)
1050 BLOCK 20,20,x,y+20,7
1060 BLOCK 20,20,x,y+60,7
1070 x=x-80
1080 END DEFine EE
1090 :
1100 DEFine PROCedure SET_ALARM
1110 CLS:CSIZE 1,1
1120 INPUT\"   ENTER THE TIME FOR THE ALARM HH:MM >";R$
1130 PRINT\"   ARE YOU SURE: ";R$;"... OK? Y/N"
1140 IF NOT INKEY$(-1)INSTR "Y":GO TO 1110: END IF
1150 CSIZE 0,0
1160 END DEFine SET_ALARM
1170 :
1180 DEFine PROCedure SET_HOUR
1190 CLS:CSIZE 1,1
1200 INPUT\"   ENTER EXACT TIME HH:MM >";W$
1210 ORE=W$(1 TO 2):MINUTI=W$(4 TO 5):SDATE 1989,3,12,ORE,MINUTI,0
1220 CSIZE 0,0
1230 END DEFine SET_HOUR
1260 :
1270 R$=""
1280 init
1290 F$=""
1300 REPeat LOOP
1310 x=20:y=80
1320 E$=DATE$
1330 E$=E$(13 TO 17)
1340 IF INKEY$=CHR$(236)
1350 SET_ALARM
1360 GO TO 1280
1370 END IF
1380 IF INKEY$=CHR$(232)
1390 SET_HOUR
1400 GO TO 1280
1410 END IF
1420 IF E$=R$ AND NOT BEEPING
1430 BEEP 32767,13,2,13,2
1440 END IF
1450 IF E$=F$
1460 NEXT LOOP
1470 END IF
1480 FOR I=1 TO LEN(E$)
1490 P=CODE(E$(I))
1500 SELect ON P
1510 =CODE("0"):E0 x,y
1520 =CODE("1"):E1 x,y
1530 =CODE("2"):E2 x,y
1540 =CODE("3"):E3 x,y
1550 =CODE("4"):E4 x,y
1560 =CODE("5"):E5 x,y
1570 =CODE("6"):E6 x,y
1580 =CODE("7"):E7 x,y
1590 =CODE("8"):E8 x,y
1600 =CODE("9"):E9 x,y
1610 =CODE(":"):EE x,y
1620 END SELect
1630 x=x+110
1640 END FOR I
1650 F$=E$
1660 END REPeat LOOP

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.