EEPROM Byte Copier

Date: 1988
Type: Program
Platform(s): ZX81, TS 1000
Tags: EPROM

Copies a block of memory into the EEPROM on the Sinc-Link ZX81 EPROM board, one byte at a time. Give it the first and last addresses to copy and the first EEPROM address; for each byte it erases the cell (POKE 255 and waits until it reads back 255), writes the byte, pauses, and prints the address, the byte written and the byte read back, so you can see that it verified.

Lines 500-540 (GOTO 500) compare 2K at 14336 with 8192 and print the offset of every byte that differs. Lines 400-420 save the program to disk with the Larken ZX81 disk system (RAND USR 14336, SAVE “EPMLD.B1”): they need the Larken ROM; the rest runs on a stock ZX81. No author is printed; this is Listing 1 (EPMLD.B1) of the second part of the EPROM board article, continued from the January-February 1988 issue.

Published in Sinc-Link May-June 1988 (ZX81 EPROM Board).

Related Articles

Board layout, parts list and program listings. Continued from Sinc-Link v6 n1.

Image Gallery

Source Code

 10 SLOW
 20 LET E=0
 30 PRINT "FIRST BYTE LOCATION TO COPY"
 40 INPUT B
 50 PRINT B
 60 PRINT "LAST BYTE LOCATION TO COPY"
 70 INPUT C
 80 PRINT C
 90 PRINT "ENTER FIRST EEPROM BYTE LOCATION"
100 INPUT A
110 PRINT A
120 LET D=PEEK B
130 REM ERASE BYTE
140 POKE A,255
150 PAUSE 2
160 IF NOT PEEK A=255 THEN GOTO 140
170 REM WRITE
180 POKE A,D
190 PAUSE 1
200 SCROLL
210 REM VERIFY
220 PRINT A;",";D;TAB 16;PEEK A
230 REM NEXT ADDRESS
240 IF E=C-B THEN GOTO 300
250 LET A=A+1
260 LET B=B+1
270 GOTO 120
300 SCROLL
310 PRINT "END OF COPY"
320 STOP
400 RAND USR 14336
410 REM SAVE"EPMLD.B1"
420 RUN
500 FAST
510 FOR N=1 TO 2048
520 IF PEEK (14335+N)<>PEEK (8191+N) THEN PRINT N
530 NEXT N
540 PRINT "END"

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.