Fall of the Third Reich

Developer(s): Mark Stueber
Date: 1984
Type: Program
Platform(s): TS 2068
Tags: Strategy

Fall of the Third Reich covers the end of the war in Europe, from December 1944 to April 1945. The map of Germany and its neighbours fills the screen, and over ten turns the player moves the German panzer (P), grenadier (G) and infantry (I) units, while the computer moves the Western Allied and Soviet armies in from both sides, shown in red and green. Units are moved one step at a time with the keys 5 to 8, 4 shows the unit again and 9 ends its move; units next to the enemy are asked whether to attack. The player wins if Berlin has not fallen at the end of turn 10, draws if it falls on the last turn, and loses if it falls sooner.

The title screen reads “FALL OF THE THIRD REICH / DEC. 44 TO APRIL 45 / ©1984 by Mark L Stueber”. Two reviews of it are linked below.

Program Analysis

The program is laid out like Stueber’s Ardennes: terrain in a$(), the board in b() (values 1–3 for the player’s unit types and 4–9 for the two enemy forces), and the player’s 30 units in g(), x() and y(). Lines 150–500 handle the player’s moves, 6000 onwards the end-of-turn checks and victory conditions, and 8000 onwards the computer’s moves, which test the eight neighbouring squares of each enemy unit. Subroutines 9800 and 9807 choose the colour and letter for a unit. The map is a SCREEN$ loaded from the tape, and the unit graphics are a 168-byte CODE block at 65368.

Notable Techniques

  • Ink colours separate the sides: black for the player, red and green for the enemy armies, with INVERSE 1 so units show as solid blocks over the map.
  • Movement allowances differ by unit type (lines 176–179), and moves into rivers or occupied squares are refused with a flashing X (9900).

No original tape of this game is known to survive. The only copy, on a Larken disk, was a 48K memory image of the TS2068 taken while the game was running, loaded back with a single LOAD ""CODE. For this tape, the BASIC program and its variables were cut out of that image at the addresses given by the system variables and saved as a normal program; the unit graphics were taken from the image, and the map screen from the disk. The program’s own SAVE line shows the original tape layout (“war”, “graphic”, “map”), which this tape follows. Tested in ZEsarUX: the map, the starting positions and the first moves.

Related Products

As the German player your devastated army must hold off the Allies and Russians on two different fronts, and hold Berlin as long as possible.

Related Articles

Review of the program by Mark Stueber.
This is one of the few games I’ve had for the 2068. I’ve never brought a “war game” before but the ads got to me.

Image Gallery

Source Code

    1 FLASH 1: PRINT AT 3,8;"LEAVE TAPE RUNNING": FLASH 0
    2 PRINT AT 10,5;"FALL OF THE THIRD REICH": PRINT AT 12,7;"DEC. 44 TO APRIL 45"
    3 PRINT AT 15,5;"*1984 by Mark L Stueber"
    4 INK 7: PAPER 7
    5 RANDOMIZE 
    6 ON ERR GO TO 8
    8 LOAD ""CODE 
    9 LOAD "map"SCREEN$ 
   10 PAPER 6
   20 FOR t=1 TO 10
   21 INVERSE 0: PAPER 1: INK 7: PRINT AT 0,0;t
   22 PAPER 6
   25 BORDER 0
   30 IF t>1 THEN GO TO 150
   40 FOR c=2 TO 23
   50 FOR d=2 TO 33
   53 IF b(c,d)>3 THEN GO TO 60
   55 NEXT d: NEXT c: GO TO 100
   60 LET rs=b(c,d): GO SUB 9800
   80 INVERSE 1: PRINT AT c-2,d-2;c$
   90 NEXT d: NEXT c: GO TO 100
  100 INK 0
  102 FOR i=1 TO 30
  103 INK 0
  104 IF g(i)>0 THEN GO TO 110
  105 NEXT i: GO TO 150
  110 GO SUB 9807
  116 INVERSE 1: PRINT AT x(i),y(i);b$
  117 LET b(x(i)+2,y(i)+2)=g(i)
  118 NEXT i
  150 FOR i=1 TO 30
  155 IF g(i)>0 THEN GO TO 165
  160 NEXT i: GO TO 7000
  165 IF b(x(i)+2,y(i)+2)>0 THEN GO TO 170
  166 GO TO 160
  170 IF g(i)=1 THEN LET b$="P"
  172 IF g(i)=2 THEN LET b$="G"
  175 IF g(i)=3 THEN LET b$="I"
  176 LET m=5
  177 IF g(i)=1 THEN LET m=6
  179 IF g(i)=3 THEN LET m=4
  180 FOR n=1 TO m
  181 IF b(x(i)+1,y(i)+2)>3 OR b(x(i)+2,y(i)+1)>3 OR b(x(i)+2,y(i)+3)>3 OR b(x(i)+1,y(i)+3)>3 OR b(x(i)+3,y(i)+3)>3 OR b(x(i)+3,y(i)+2)>3 OR b(x(i)+1,y(i)+1)>3 OR b(x(i)+3,y(i)+1)>3 THEN GO TO 3000
  182 FOR j=1 TO 3
  184 GO SUB 600
  185 PAUSE 8: INVERSE 1: PRINT INK 0;AT x(i),y(i);b$: PAUSE 7: NEXT j
  187 ON ERR GO TO 189
  189 INPUT k
  190 IF k=4 THEN GO TO 182
  191 IF k=9 THEN NEXT i: GO TO 7000
  193 IF k=5 THEN GO TO 200
  195 IF k=6 THEN GO TO 300
  197 IF k=7 THEN GO TO 400
  198 IF k=8 THEN GO TO 500
  199 GO TO 189
  200 IF y(i)<=1 OR b(x(i)+2,y(i)+1)>0 THEN GO TO 9900
  202 IF c(x(i)+1,y(i))=3 THEN GO TO 9900
  204 IF ((m=4 AND n>3) OR (m=5 AND n>4) OR (m=6 AND n>5)) AND (c(x(i)+1,y(i))>0) THEN GO TO 9900
  206 GO SUB 600: INVERSE 1: INK 0
  208 LET b(x(i)+2,y(i)+2)=0
  209 IF c(x(i)+1,y(i))=1 OR c(x(i)+1,y(i))=2 THEN LET n=n+1
  210 LET y(i)=y(i)-1
  212 PRINT AT x(i),y(i);b$: BEEP .2,-7
  214 LET b(x(i)+2,y(i)+2)=g(i)
  220 NEXT n: GO TO 3000
  300 IF x(i)>=21 OR b(x(i)+3,y(i)+2)>0 THEN GO TO 9900
  302 IF c(x(i)+2,y(i)+1)=3 THEN GO TO 9900
  304 IF ((m=4 AND n>3) OR (m=5 AND n>4) OR (m=6 AND n>5)) AND (c(x(i)+2,y(i)+1)>0) THEN GO TO 9900
  306 GO SUB 600: INVERSE 1: INK 0
  308 LET b(x(i)+2,y(i)+2)=0
  309 IF c(x(i)+2,y(i)+1)=1 OR c(x(i)+2,y(i)+1)=2 THEN LET n=n+1
  310 LET x(i)=x(i)+1
  312 PRINT AT x(i),y(i);b$: BEEP .2,-7
  314 LET b(x(i)+2,y(i)+2)=g(i)
  320 NEXT n: GO TO 3000
  400 IF x(i)=0 OR b(x(i)+1,y(i)+2)>0 THEN GO TO 9900
  402 IF c(x(i),y(i)+1)=3 THEN GO TO 9900
  404 IF ((m=4 AND n>3) OR (m=5 AND n>4) OR (m=6 AND n>5)) AND (c(x(i),y(i)+1)>0) THEN GO TO 9900
  406 GO SUB 600: INVERSE 1: INK 0
  408 LET b(x(i)+2,y(i)+2)=0
  409 IF c(x(i),y(i)+1)=1 OR c(x(i),y(i)+1)=2 THEN LET n=n+1
  410 LET x(i)=x(i)-1
  412 PRINT AT x(i),y(i);b$: BEEP .2,-7
  414 LET b(x(i)+2,y(i)+2)=g(i)
  420 NEXT n: GO TO 3000
  500 IF y(i)>31 OR b(x(i)+2,y(i)+3)>0 THEN GO TO 9900
  502 IF c(x(i)+1,y(i)+2)=3 THEN GO TO 9900
  504 IF ((m=4 AND n>3) OR (m=5 AND n>4) OR (m=6 AND n>5)) AND (c(x(i)+1,y(i)+2)>0) THEN GO TO 9900
  506 GO SUB 600: INVERSE 1: INK 0
  508 LET b(x(i)+2,y(i)+2)=0
  509 IF c(x(i)+1,y(i)+2)=1 OR c(x(i)+1,y(i)+2)=2 THEN LET n=n+1
  510 LET y(i)=y(i)+1
  512 PRINT AT x(i),y(i);b$: BEEP .2,-7
  514 LET b(x(i)+2,y(i)+2)=g(i)
  520 NEXT n: GO TO 3000
  600 INVERSE 0: INK 6
  603 IF a$(x(i)+1,y(i)+1)<>" " THEN INK 1
  605 IF a$(x(i)+1,y(i)+1)="r" THEN INK 3
  608 IF a$(x(i)+1,y(i)+1)="q" THEN INK 0
  610 IF a$(x(i)+1,y(i)+1)=" " THEN INK 6
  612 PRINT AT x(i),y(i);a$(x(i)+1,y(i)+1)
  614 IF x(i)=9 AND y(i)=4 THEN OVER 1: INK 1: PRINT AT x(i),y(i);"b": OVER 0: RETURN 
  616 IF (x(i)=10 AND y(i)=4) OR (x(i)=7 AND y(i)=3) THEN OVER 1: INK 0: PRINT AT x(i),y(i);"*": OVER 0: RETURN 
  618 RETURN 
 2000 BORDER 4
 2001 FOR a=2 TO 23
 2002 FOR b=2 TO 33: LET x=8: LET y=14
 2004 IF b(a,b)>3 THEN GO TO 2010
 2006 NEXT b: NEXT a: GO TO 8000
 2010 LET n=0: LET e=a: LET f=b
 2011 LET rs=b(e,f)
 2012 IF b(e,f+1)=1 OR b(e,f-1)=1 OR b(e+1,f+1)=1 OR b(e+1,f-1)=1 OR b(e-1,f-1)=1 OR b(e-1,f+1)=1 OR b(e+1,f)=1 OR b(e-1,f)=1 THEN GO TO 2006
 2014 IF b(e,f+1)=2 OR b(e,f-1)=2 OR b(e+1,f+1)=2 OR b(e+1,f-1)=2 OR b(e-1,f-1)=2 OR b(e-1,f+1)=2 OR b(e+1,f)=2 OR b(e-1,f)=2 THEN GO TO 2006
 2015 IF b(e,f+1)=3 OR b(e,f-1)=3 OR b(e+1,f+1)=3 OR b(e+1,f-1)=3 OR b(e-1,f-1)=3 OR b(e-1,f+1)=3 OR b(e+1,f)=3 OR b(e-1,f)=3 THEN GO TO 2006
 2020 IF n>m THEN GO TO 2006
 2022 LET m=4: IF rs=6 OR rs=8 THEN LET m=6
 2023 IF rs=5 THEN LET m=7
 2024 IF rs=4 THEN LET m=8
 2026 LET z5=0
 2028 LET z1=0
 2037 IF y>f+1 THEN GO TO 2100
 2038 IF y<f-1 THEN GO TO 2110
 2039 IF x<e-1 THEN GO TO 2120
 2040 IF x>e-1 THEN GO TO 2130
 2100 LET z1=0: GO SUB 5000
 2102 IF z5=5 THEN GO TO 2012
 2103 GO SUB 5200
 2104 IF z5=5 THEN GO TO 2012
 2105 LET z1=1: GO SUB 5200
 2106 IF z5=5 THEN GO TO 2012
 2109 NEXT b: NEXT a: GO TO 8000
 2110 LET z1=1: GO SUB 5000
 2111 IF z5=5 THEN GO TO 2012
 2113 LET z1=1: GO SUB 5200
 2114 IF z5=5 THEN GO TO 2012
 2115 LET z1=0: GO SUB 5200
 2116 IF z5=5 THEN GO TO 2012
 2119 GO TO 2109
 2120 LET z1=0: GO SUB 5200
 2122 IF z5=5 THEN GO TO 2012
 2123 LET z1=1: GO SUB 5000
 2124 IF z5=5 THEN GO TO 2012
 2125 LET z1=0: GO SUB 5000
 2127 IF z5=5 THEN GO TO 2012
 2129 GO TO 2109
 2130 LET z1=1: GO SUB 5200
 2131 GO TO 2122
 3000 INVERSE 0: INK 2
 3010 IF b(x(i)+1,y(i)+2)>3 OR b(x(i)+2,y(i)+1)>3 OR b(x(i)+2,y(i)+3)>3 OR b(x(i)+1,y(i)+3)>3 OR b(x(i)+3,y(i)+3)>3 OR b(x(i)+3,y(i)+2)>3 OR b(x(i)+1,y(i)+1)>3 OR b(x(i)+3,y(i)+1)>3 THEN GO TO 3015
 3012 PAPER 6: NEXT i: GO TO 7000
 3015 FOR j=1 TO 3: GO SUB 600: PAUSE 8: INVERSE 1: PRINT INK 0;AT x(i),y(i);b$: PAUSE 7: NEXT j
 3035 INVERSE 0: INK 0: PRINT AT 0,9;"ATTACK?"
 3040 INPUT z$
 3050 IF z$="n" THEN PAPER 6: INK 1: PRINT AT 0,9;"::::::::::::::": NEXT i: GO TO 7000
 3060 PRINT AT 0,9;"ENTER #": INPUT z
 3065 INK 1: PRINT AT 0,9;"::::::::::::::"
 3068 PAPER 6
 3072 IF z=1 AND b(x(i)+1,y(i)+1)>3 THEN LET d(x(i)+1,y(i)+1)=1: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3074 IF z=2 AND b(x(i)+1,y(i)+2)>3 THEN LET d(x(i)+1,y(i)+1)=2: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3076 IF z=3 AND b(x(i)+1,y(i)+3)>3 THEN LET d(x(i)+1,y(i)+1)=3: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3077 IF z=4 AND b(x(i)+2,y(i)+1)>3 THEN LET d(x(i)+1,y(i)+1)=4: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3078 IF z=5 AND b(x(i)+2,y(i)+3)>3 THEN LET d(x(i)+1,y(i)+1)=5: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3079 IF z=6 AND b(x(i)+3,y(i)+1)>3 THEN LET d(x(i)+1,y(i)+1)=6: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3080 IF z=7 AND b(x(i)+3,y(i)+2)>3 THEN LET d(x(i)+1,y(i)+1)=7: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3081 IF z=8 AND b(x(i)+3,y(i)+3)>3 THEN LET d(x(i)+1,y(i)+1)=8: LET n1=1: PAPER 6: NEXT i: GO TO 7000
 3085 PRINT AT 0,9;"INVALID": PAUSE 50: GO TO 3015
 3090 PAPER 6
 5000 LET n=n+1
 5001 IF n>m THEN RETURN 
 5002 IF z1=0 AND b(e,f+1)=0 AND c(e-1,f)=1 AND n>m THEN LET m=m+1
 5004 IF z1=1 AND b(e,f-1)=0 AND c(e-1,f-2)=1 AND n>m THEN LET m=m+1
 5010 IF z1=0 AND b(e,f+1)=0 AND c(e-1,f)<3 THEN LET b(e,f)=0: BEEP .1,5: LET b(e,f+1)=(rs*(-1)): GO SUB 9000: LET f=f+1: GO SUB 9800: INVERSE 1: PRINT AT e-2,f-2;c$: LET z5=5: RETURN 
 5012 IF z1=1 AND b(e,f-1)=0 AND c(e-1,f-2)<3 THEN LET b(e,f)=0: BEEP .1,5: LET b(e,f-1)=(rs*(-1)): GO SUB 9000: LET f=f-1: GO SUB 9800: INVERSE 1: PRINT AT e-2,f-2;c$: LET z5=5: RETURN 
 5014 RETURN 
 5200 LET n=n+1
 5201 IF n>m THEN RETURN 
 5203 IF z1=0 AND b(e-1,f)=0 AND c(e-2,f-1)=1 AND n>m THEN LET m=m+1
 5205 IF z1=1 AND b(e+1,f)=0 AND c(e,f-1)=1 AND n>m THEN LET m=m+1
 5210 IF z1=0 AND b(e-1,f)=0 AND c(e-2,f-1)<3 THEN LET b(e,f)=0: BEEP .1,5: LET b(e-1,f)=(rs*(-1)): GO SUB 9000: LET e=e-1: GO SUB 9800: INVERSE 1: PRINT AT e-2,f-2;c$: LET z5=5: RETURN 
 5212 IF z1=1 AND b(e+1,f)=0 AND c(e,f-1)<3 THEN LET b(e,f)=0: BEEP .1,5: LET b(e+1,f)=(rs*(-1)): GO SUB 9000: LET e=e+1: GO SUB 9800: INVERSE 1: PRINT AT e-2,f-2;c$: LET z5=5: RETURN 
 5214 RETURN 
 6000 FOR a=2 TO 23
 6001 FOR b=2 TO 33
 6004 IF b(a,b)<0 THEN LET rs=b(a,b): LET rs=rs*(-1): LET b(a,b)=rs
 6005 NEXT b: NEXT a: RETURN 
 6006 GO SUB 6000
 6007 BORDER 5: LET re=0: LET ge=0: LET ae=0
 6010 IF t>1 AND t<6 THEN LET re=2
 6011 IF t>5 THEN LET re=1
 6012 IF t>5 THEN LET re=1
 6015 IF t>1 THEN LET ae=2
 6020 IF t>1 THEN LET ge=1
 6025 IF t=2 OR t=4 OR t=6 OR t=8 THEN LET ge=2
 6030 IF b(8,14)>3 OR b(8,15)>3 OR b(8,13)>3 OR b(9,13)>3 OR b(9,14)>3 OR b(9,15)>3 OR b(7,13)>3 OR b(7,14)>3 OR b(7,15)>3 THEN LET ge=0: GO SUB 6100
 6032 IF ge=0 AND re=0 AND ae=0 THEN NEXT t
 6040 IF re>0 THEN GO TO 6050
 6043 IF ae>0 THEN GO TO 6060
 6048 IF ge>0 THEN GO TO 6070
 6049 GO TO 6075
 6050 LET a=INT (RND*8)+3: LET b(a+2,32)=7: INVERSE 1: INK 2: PRINT AT a,30;"R": LET re=re-1: GO TO 6040
 6060 LET a=INT (RND*8)+7: LET b(a+2,3)=5: INVERSE 1: INK 4: PRINT AT a,1;"A": LET ae=ae-1: GO TO 6043
 6070 LET a=14: FOR i=1 TO 30
 6071 IF g(i)>0 THEN NEXT i: GO TO 6077
 6072 IF b(9,a)=0 THEN INK 0: LET b(9,a)=3: INVERSE 1: PRINT AT 7,a-2;"I": LET ge=ge-1: LET g(i)=3: LET x(i)=7: LET y(i)=a-2: LET a=a+1: IF ge>0 THEN NEXT i
 6075 NEXT t
 6077 INVERSE 1: INK 0: PRINT AT 10,1;"YOU WIN - BERLIN DID NOT FALL": STOP 
 6100 IF (b(8,14)=0 OR b(8,14)>3) AND t<10 THEN PRINT INVERSE 1; INK 1;AT 15,7;"YOU LOSE - BERLIN FELL!": STOP 
 6101 IF (b(8,14)=0 OR b(8,14)>3) AND t=10 THEN PRINT INVERSE 1; INK 1;AT 15,2;"DRAW - BERLIN FELL ON TURN 10": STOP 
 6102 RETURN 
 7000 IF n1=0 THEN GO TO 2000
 7003 BORDER 2: LET n1=0: LET g2=0: LET gs2=0
 7006 FOR c=1 TO 22: FOR d=1 TO 32
 7007 ON ERR GO TO 7015
 7010 IF d(c,d)>0 THEN GO TO 7020
 7015 NEXT d: NEXT c: GO TO 2000
 7020 FOR i=1 TO 30
 7023 IF x(i)=c-1 AND y(i)=d-1 THEN GO TO 7030
 7026 NEXT i: GO TO 7015
 7030 LET gs=2: IF g(i)=1 THEN LET gs=5
 7033 IF g(i)=2 THEN LET gs=4
 7034 LET u=0: LET w=0: LET g2=0
 7035 IF d(c,d)=1 THEN LET e=c-1: LET f=d-1: LET d(c,d)=0: GO TO 7050
 7036 IF d(c,d)=2 THEN LET e=c-1: LET f=d: LET d(c,d)=0: GO TO 7050
 7037 IF d(c,d)=3 THEN LET e=c-1: LET f=d+1: LET d(c,d)=0: GO TO 7050
 7038 IF d(c,d)=4 THEN LET e=c: LET f=d-1: LET d(c,d)=0: GO TO 7050
 7039 IF d(c,d)=5 THEN LET e=c: LET f=d+1: LET d(c,d)=0: GO TO 7050
 7040 IF d(c,d)=6 THEN LET e=c+1: LET f=d-1: LET d(c,d)=0: GO TO 7050
 7042 IF d(c,d)=7 THEN LET e=c+1: LET f=d: LET d(c,d)=0: GO TO 7050
 7044 IF d(c,d)=8 THEN LET e=c+1: LET f=d+1: LET d(c,d)=0: GO TO 7050
 7048 GO TO 7015
 7050 IF d(e,f-1)=5 THEN LET w=e: LET u=f-1: LET d(e,f-1)=0: GO TO 7090
 7051 IF d(e,f+1)=4 THEN LET w=e: LET u=f+1: LET d(e,f+1)=0: GO TO 7090
 7052 IF d(e+1,f+1)=1 THEN LET w=e+1: LET u=f+1: LET d(e+1,f+1)=0: GO TO 7090
 7053 IF e>1 THEN LET e=e: IF d(e-1,f+1)=6 THEN LET w=e-1: LET u=f+1: LET d(e-1,f+1)=0: GO TO 7090
 7054 IF d(e+1,f-1)=3 THEN LET w=e+1: LET u=f-1: LET d(e+1,f-1)=0: GO TO 7090
 7055 IF e<1 THEN LET e=e: IF d(e-1,f-1)=8 THEN LET w=e-1: LET u=f-1: LET d(e-1,f-1)=0: GO TO 7090
 7056 IF e<1 THEN LET e=e: IF d(e-1,f)=7 THEN LET w=e-1: LET u=f: LET d(e-1,f)=0: GO TO 7090
 7057 IF d(e+1,f)=2 THEN LET w=e+1: LET u=f: LET d(e+1,f)=0: GO TO 7090
 7059 GO TO 7100
 7090 LET g2=1
 7091 FOR j=1 TO 30
 7092 IF x(j)=w-1 AND y(j)=u-1 THEN GO TO 7095
 7093 NEXT j: LET g2=0: GO TO 7100
 7095 LET gs2=2: IF g(j)=1 THEN LET gs2=5
 7096 IF g(j)=2 THEN LET gs2=4
 7100 LET tgs=gs+gs2
 7102 LET rs=b(e+1,f+1)
 7104 IF rs=4 OR rs=8 THEN LET ds=4
 7105 IF rs=5 OR rs=9 THEN LET ds=6
 7107 IF rs=7 THEN LET ds=7
 7108 IF rs=6 THEN LET ds=8
 7109 IF c(e,f)>0 THEN LET ds=ds*2
 7120 LET ratio=tgs/ds
 7122 LET dice=INT (RND*6)
 7124 LET roll=dice+ratio: IF ratio<1 THEN LET roll=dice-3
 7125 SOUND 6,15;7,7;8,16;9,16;10,16;12,16;13,0
 7130 IF roll>7 THEN GO TO 7160
 7131 IF roll>5 THEN GO TO 7200
 7132 IF roll>1 THEN GO TO 7300
 7133 IF roll>-1 THEN GO TO 7400
 7135 GO TO 7500
 7160 LET b(e+1,f+1)=0: LET e=e+1: LET f=f+1: GO SUB 9000
 7163 LET b(x(i)+2,y(i)+2)=0: GO SUB 600
 7166 LET x(i)=e-2: LET y(i)=f-2
 7168 LET b(x(i)+2,y(i)+2)=g(i)
 7170 GO SUB 9807: PRINT INVERSE 1;AT x(i),y(i);b$: GO TO 7015
 7200 LET b(e+1,f+1)=0: LET e=e+1: LET f=f+1: GO SUB 9000
 7202 LET b(x(i)+2,y(i)+2)=0: LET g(i)=0: GO SUB 600
 7204 GO TO 7015
 7207 LET i=j: LET b(x(i)+2,y(i)+2)=0: GO SUB 600
 7210 LET x(i)=e-2: LET y(i)=f-2
 7212 LET b(x(i)+2,y(i)+2)=g(i): GO SUB 9807
 7218 INVERSE 1: PRINT AT x(i),y(i);b$: GO TO 7015
 7300 IF (b(e+1,f+2)>0 AND b(e+1,f+2)<4) AND (b(e+1,f)>0 AND b(e+1,f)<4) THEN LET b(e+1,f+1)=0: LET e=e+1: LET f=f+1: GO SUB 9000: GO TO 7015
 7302 IF (b(e,f+1)>0 AND b(e,f+1)<4) AND (b(e+2,f+1)>0 AND b(e+2,f+1)<4) THEN LET b(e+1,f+1)=0: LET e=e+1: LET f=f+1: GO SUB 9000: GO TO 7015
 7304 LET b(x(i)+2,y(i)+2)=0: GO SUB 600
 7306 LET rs=b(e+1,f+1): LET x(i)=e-1: LET y(i)=f-1
 7308 LET b(x(i)+2,y(i)+2)=g(i): GO SUB 9807
 7310 INVERSE 1: PRINT AT x(i),y(i);b$
 7312 IF rs=0 THEN GO TO 7015
 7313 GO SUB 9800
 7315 IF f<12 THEN GO TO 7350
 7318 INVERSE 1: IF b(e+1,f+2)=0 AND c(e,f+1)<3 THEN LET b(e+1,f+2)=rs: PRINT AT e-1,f;c$: GO TO 7015
 7319 IF b(e+2,f+2)=0 AND c(e+1,f+1)<3 THEN LET b(e+2,f+2)=rs: PRINT AT e,f;c$: GO TO 7015
 7320 IF b(e,f+2)=0 AND c(e-1,f+1)<3 THEN LET b(e,f+2)=rs: PRINT AT e-2,f;c$: GO TO 7015
 7321 IF b(e,f+1)=0 AND c(e-1,f)<3 THEN LET b(e,f+1)=rs: PRINT AT e-2,f-1;c$: GO TO 7015
 7322 IF b(e+2,f+1)=0 AND c(e+1,f)<3 THEN LET b(e+2,f+1)=rs: PRINT AT e,f-1;c$: GO TO 7015
 7325 LET rs=0: GO TO 7015
 7350 INVERSE 1: IF b(e+1,f)=0 AND c(e,f-1)<3 THEN LET b(e+1,f)=rs: PRINT AT e-1,f-2;c$: GO TO 7015
 7351 IF b(e+2,f)=0 AND c(e+1,f-1)<3 THEN LET b(e+2,f)=rs: PRINT AT e,f-2;c$: GO TO 7015
 7352 IF b(e,f)=0 AND c(e-1,f-1)<3 THEN LET b(e,f)=rs: PRINT AT e-2,f-2;c$: GO TO 7015
 7353 IF b(e,f+1)=0 AND c(e-1,f)<3 THEN LET b(e,f+1)=rs: PRINT AT e-2,f-1;c$: GO TO 7015
 7354 IF b(e+2,f+1)=0 AND c(e+1,f)<3 THEN LET b(e+2,f+1)=rs: PRINT AT e,f-1;c$: GO TO 7015
 7370 LET rs=0: GO TO 7015
 7400 IF b(x(i)+2,y(i)+3)>3 AND b(x(i)+2,y(i)+1)>3 THEN LET g(i)=0: GO SUB 600: GO TO 7410
 7402 IF b(x(i)+1,y(i)+2)>3 AND b(x(i)+3,y(i)+2)>3 THEN LET g(i)=0: GO SUB 600: GO TO 7410
 7404 GO SUB 600
 7410 LET rs=b(e+1,f+1): LET b(e+1,f+1)=0: LET e=e+1: LET f=f+1: GO SUB 9000
 7412 LET b(x(i)+2,y(i)+2)=rs: GO SUB 9800: INVERSE 1: PRINT AT x(i),y(i);c$
 7414 IF g(i)>0 THEN GO TO 7420
 7418 GO TO 7015
 7420 IF g(i)>0 AND y(i)>15 THEN GO TO 7430
 7421 IF g(i)>0 AND y(i)<16 THEN GO TO 7450
 7425 GO TO 7448
 7430 IF b(x(i)+2,y(i)+1)=0 AND c(x(i)+1,y(i))<3 THEN LET b(x(i)+2,y(i)+1)=g(i): GO SUB 9807: LET y(i)=y(i)-1: PRINT AT x(i),y(i);b$: GO TO 7448
 7431 IF b(x(i)+1,y(i)+1)=0 AND c(x(i),y(i))<3 THEN LET b(x(i)+1,y(i)+1)=g(i): GO SUB 9807: LET y(i)=y(i)-1: LET x(i)=x(i)-1: PRINT AT x(i),y(i);b$: GO TO 7448
 7432 IF b(x(i)+3,y(i)+1)=0 AND c(x(i)+2,y(i))<3 THEN LET b(x(i)+3,y(i)+1)=g(i): GO SUB 9807: LET y(i)=y(i)-1: LET x(i)=x(i)+1: PRINT AT x(i),y(i);b$: GO TO 7448
 7434 LET g(i)=0
 7448 IF g2>0 THEN LET i=j: LET g2=0: GO SUB 600: LET j=0: GO TO 7420
 7449 GO TO 7015
 7450 IF b(x(i)+2,y(i)+3)=0 AND c(x(i)+1,y(i)+2)<3 THEN LET b(x(i)+2,y(i)+3)=g(i): GO SUB 9807: LET y(i)=y(i)+1: PRINT AT x(i),y(i);b$: GO TO 7448
 7451 IF b(x(i)+1,y(i)+3)=0 AND c(x(i),y(i)+2)<3 THEN LET b(x(i)+1,y(i)+3)=g(i): GO SUB 9807: LET y(i)=y(i)+1: LET x(i)=x(i)-1: PRINT AT x(i),y(i);b$: GO TO 7448
 7452 IF b(x(i)+3,y(i)+3)=0 AND c(x(i)+2,y(i)+2)<3 THEN LET b(x(i)+3,y(i)+3)=g(i): GO SUB 9807: LET y(i)=y(i)+1: LET x(i)=x(i)+1: PRINT AT x(i),y(i);b$: GO TO 7448
 7455 GO TO 7434
 7500 LET g(i)=0: LET b(x(i)+2,y(i)+2)=0: GO SUB 600
 7505 LET b(e+1,f+1)=0: LET e=e+1: LET f=f+1: GO SUB 9000
 7510 LET e=c: LET f=d: LET b(x(i)+1,y(i)+1)=rs
 7515 GO SUB 9800: INVERSE 1: PRINT AT x(i),y(i);c$
 7520 IF g2=0 THEN GO TO 7015
 7525 LET b(w+1,u+1)=0: LET i=j: GO SUB 600: LET g(i)=0: GO TO 7015
 8000 BORDER 2: GO SUB 6000
 8001 FOR i=1 TO 30
 8002 ON ERR GO TO 8008
 8003 IF g(i)=0 THEN NEXT i: GO TO 6006
 8004 LET rat=0
 8006 IF b(x(i)+2,y(i)+3)>3 OR b(x(i)+2,y(i)+1)>3 OR b(x(i)+1,y(i)+1)>3 OR b(x(i)+1,y(i)+2)>3 OR b(x(i)+1,y(i)+3)>3 OR b(x(i)+3,y(i)+1)>3 OR b(x(i)+3,y(i)+2)>3 OR b(x(i)+3,y(i)+3)>3 THEN GO TO 8010
 8008 NEXT i: GO TO 6006
 8010 IF b(x(i)+2,y(i)+3)>3 THEN LET rs=b(x(i)+2,y(i)+3): LET e=x(i)+2: LET f=y(i)+3: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8011 IF b(x(i)+2,y(i)+1)>3 THEN LET rs=b(x(i)+2,y(i)+1): LET e=x(i)+2: LET f=y(i)+1: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8012 IF b(x(i)+1,y(i)+1)>3 THEN LET rs=b(x(i)+1,y(i)+1): LET e=x(i)+1: LET f=y(i)+1: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8013 IF b(x(i)+1,y(i)+2)>3 THEN LET rs=b(x(i)+1,y(i)+2): LET e=x(i)+1: LET f=y(i)+2: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8014 IF b(x(i)+1,y(i)+3)>3 THEN LET rs=b(x(i)+1,y(i)+3): LET e=x(i)+1: LET f=y(i)+3: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8015 IF b(x(i)+2,y(i)+1)>3 THEN LET rs=b(x(i)+2,y(i)+1): LET e=x(i)+2: LET f=y(i)+1: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8016 IF b(x(i)+3,y(i)+1)>3 THEN LET rs=b(x(i)+3,y(i)+1): LET e=x(i)+3: LET f=y(i)+1: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8017 IF b(x(i)+3,y(i)+2)>3 THEN LET rs=b(x(i)+3,y(i)+2): LET e=x(i)+3: LET f=y(i)+2: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8018 IF b(x(i)+3,y(i)+3)>3 THEN LET rs=b(x(i)+3,y(i)+3): LET e=x(i)+3: LET f=y(i)+3: LET b(e,f)=b(e,f)*(-1): GO SUB 8030
 8020 GO TO 8040
 8031 IF rs=4 OR rs=7 THEN LET rat=rat+7
 8032 IF rs=5 OR rs=8 THEN LET rat=rat+6
 8034 IF rs=6 THEN LET rat=rat+4
 8037 IF rs=9 THEN LET rat=rat+5
 8039 RETURN 
 8040 LET gd=4: IF g(i)=1 THEN LET gd=5
 8042 IF g(i)=3 THEN LET gd=3
 8050 IF c(x(i)+1,y(i)+1)=1 THEN LET gd=gd*2
 8051 IF c(x(i)+1,y(i)+1)=2 THEN LET gd=gd*3
 8053 LET ratio=rat/gd
 8055 IF ratio<1 THEN NEXT i: GO TO 6006
 8057 LET dice=INT (RND*6)+1: LET roll=ratio+dice
 8058 SOUND 6,15;7,7;8,16;9,16;10,16;12,16;13,0
 8060 IF roll>8 THEN GO TO 8100
 8062 IF roll>6 THEN GO TO 8200
 8064 IF roll>2 THEN GO TO 8300
 8070 GO TO 8400
 8100 LET g(i)=0: GO SUB 600
 8102 LET b(e,f)=0: LET b(x(i)+2,y(i)+2)=rs: GO SUB 9000: GO SUB 9800: PRINT AT x(i),y(i);c$: NEXT i: GO TO 6006
 8200 LET g(i)=0: GO SUB 600: LET b(x(i)+2,y(i)+2)=0: LET b(e,f)=0: GO SUB 9000: NEXT i: GO TO 6006
 8300 IF b(x(i)+1,y(i)+2)<0 AND b(x(i)+3,y(i)+2)<0 THEN LET g(i)=0: GO SUB 600: LET b(e,f)=0: GO SUB 9000: GO SUB 9800: LET b(x(i)+2,y(i)+2)=rs: PRINT AT x(i),y(i);c$: NEXT i: GO TO 6006
 8305 GO SUB 9000: GO SUB 9800: LET b(x(i)+2,y(i)+2)=rs: LET b(e,f)=0: PRINT AT x(i),y(i);c$
 8307 GO SUB 9807
 8310 IF y(i)>12 THEN GO TO 8350
 8315 IF b(x(i)+2,y(i)+3)=0 AND c(x(i)+1,y(i)+2)<3 THEN LET y(i)=y(i)+1: LET b(x(i)+2,y(i)+2)=g(i): PRINT AT x(i),y(i);b$: NEXT i: GO TO 6006
 8316 IF b(x(i)+1,y(i)+3)=0 AND c(x(i),y(i)+2)<3 THEN LET y(i)=y(i)+1: LET x(i)=x(i)-1: LET b(x(i)+2,y(i)+2)=g(i): PRINT AT x(i),y(i);b$: NEXT i: GO TO 6006
 8317 IF b(x(i)+3,y(i)+3)=0 AND c(x(i)+2,y(i)+2)<3 THEN LET y(i)=y(i)+1: LET x(i)=x(i)+1: LET b(x(i)+2,y(i)+2)=g(i): PRINT AT x(i),y(i);b$: NEXT i: GO TO 6006
 8320 LET g(i)=0: NEXT i: GO TO 6006
 8350 IF b(x(i)+2,y(i)+1)=0 AND c(x(i)+1,y(i))<3 THEN LET y(i)=y(i)-1: LET b(x(i)+2,y(i)+2)=g(i): PRINT AT x(i),y(i);b$: NEXT i: GO TO 6006
 8351 IF b(x(i)+1,y(i)+1)=0 AND c(x(i),y(i))<3 THEN LET y(i)=y(i)-1: LET x(i)=x(i)-1: LET b(x(i)+2,y(i)+2)=g(i): PRINT AT x(i),y(i);b$: NEXT i: GO TO 6006
 8355 IF b(x(i)+3,y(i)+1)=0 AND c(x(i)+2,y(i))<3 THEN LET y(i)=y(i)-1: LET x(i)=x(i)+1: LET b(x(i)+2,y(i)+2)=g(i): PRINT AT x(i),y(i);b$: NEXT i: GO TO 6006
 8360 LET g(i)=0: NEXT i: GO TO 6006
 8400 LET b(e,f)=0: GO SUB 9000: GO SUB 9800
 8410 IF f>14 THEN GO TO 8450
 8415 IF b(e,f-1)=0 AND c(e-1,f)<3 THEN LET b(e,f-1)=rs*(-1): PRINT AT e-2,f-3;c$: NEXT i: GO TO 6006
 8417 IF b(e+1,f-1)=0 AND c(e,f-2)<3 THEN LET b(e+1,f-1)=rs*(-1): PRINT AT e-1,f-3;c$: NEXT i: GO TO 6006
 8418 IF b(e-1,f-1)=0 AND c(e-2,f-2)<3 THEN LET b(e-1,f-1)=rs*(-1): PRINT AT e+1-3,f-3;c$: NEXT i: GO TO 6006
 8420 NEXT i: GO TO 6006
 8450 IF b(e,f+1)=0 AND c(e-1,f)<3 THEN LET b(e,f+1)=rs*(-1): PRINT AT e-2,f-1;c$: NEXT i: GO TO 6006
 8451 IF b(e+1,f+1)=0 AND c(e,f)<3 THEN LET b(e+1,f+1)=rs*(-1): PRINT AT e-1,f-1;c$: NEXT i: GO TO 6006
 8453 IF b(e-1,f+1)=0 AND c(e-2,f)<3 THEN LET b(e-1,f+1)=rs*(-1): PRINT AT e-3,f-1;c$: NEXT i: GO TO 6006
 8455 NEXT i: GO TO 6006
 9000 INVERSE 0: INK 6
 9002 IF a$(e-1,f-1)<>" " THEN INK 2
 9003 IF a$(e-1,f-1)="r" THEN INK 3
 9004 IF a$(e-1,f-1)="q" THEN INK 0
 9005 IF a$(e-1,f-1)=" " THEN INK 6
 9007 PRINT AT e-2,f-2;a$(e-1,f-1)
 9008 IF e-2=9 AND f-2=4 THEN OVER 1: INK 1: PRINT AT e-2,f-2;"b": OVER 0: RETURN 
 9009 IF (e-2=10 AND f-2=4) OR (e-2=7 AND f-2=3) THEN OVER 1: INK 0: PRINT AT e-2,f-2;"*": OVER 0: RETURN 
 9010 RETURN 
 9800 INVERSE 1: IF rs=7 OR rs=-7 THEN INK 2: LET c$="R"
 9801 IF rs=8 OR rs=-8 THEN INK 2: LET c$="T"
 9802 IF rs=9 OR rs=-9 THEN INK 2: LET c$="I"
 9803 IF rs=4 OR rs=-4 THEN INK 4: LET c$="T"
 9804 IF rs=5 OR rs=-5 THEN INK 4: LET c$="A"
 9805 IF rs=6 OR rs=-6 THEN INK 4: LET c$="I"
 9806 RETURN 
 9807 INVERSE 1: IF g(i)=2 THEN INK 0: LET b$="G"
 9808 IF g(i)=3 THEN INK 0: LET b$="I"
 9809 IF g(i)=1 THEN INK 0: LET b$="P"
 9810 RETURN 
 9900 INVERSE 0: INK 0
 9901 FOR j=1 TO 3
 9902 PRINT AT x(i),y(i);"X": PAUSE 7: PRINT AT x(i),y(i);" ": PAUSE 7: NEXT j: GO TO 182
 9990 SAVE "war" LINE 1: SAVE "graphic" CODE 65368,168: SAVE "map"SCREEN$

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.