Hangcat

    5 REM hangcat  Version 3.0
   10 BORDER 1: PAPER 1: INK 7: CLS 
   15 GO SUB 2000
   20 PRINT AT 16,4;"Player 1 - Type in a word."
   25 PRINT AT 18,5;"(Player 2 - DON'T LOOK!)"
   50 INPUT a$
   55 IF a$="" THEN GO TO 50
   60 LET g$="-"
   70 FOR z=1 TO LEN a$-1
   80 LET g$=g$+"-"
   90 NEXT z
   95 LET u$=" "
  100 LET t=9
  110 CLS 
  111 PRINT : PRINT : PRINT AT 4,(32-LEN g$-1)/2;g$: PRINT : PRINT : PRINT 
  115 IF t<2 THEN PRINT "        You have 1 life.": GO TO 123
  120 PRINT "       You have ";t;" lives."
  123 PRINT : PRINT 
  125 IF u$<>" " THEN PRINT "Letters used=";u$
  127 PRINT : PRINT 
  130 PRINT "  GUESS A LETTER OF THE WORD."
  140 INPUT x$
  142 IF x$="" THEN GO TO 140
  143 CLS 
  145 LET u$=u$+x$
  150 LET f=0
  160 FOR z=1 TO LEN a$
  170 IF x$<>a$(z) THEN GO TO 200
  180 LET f=1
  190 LET g$(z)=x$
  200 NEXT z
  210 PRINT : PRINT : PRINT : PRINT 
  220 PRINT TAB 15-(LEN g$/2);g$
  225 PRINT : PRINT : PRINT 
  230 IF f=0 THEN PRINT TAB 11;"INCORRECT"
  240 IF f=1 THEN PRINT TAB 12;"CORRECT"
  245 PRINT : PRINT 
  250 IF f=0 THEN LET t=t-1
  260 IF t>0 AND g$<>a$ THEN GO TO 115
  270 IF g$<>a$ THEN PRINT "        "; FLASH 1;"YOU'RE A GONER.": BEEP 0.7,1: BEEP 0.5,1: BEEP 1,6
  280 IF g$=a$ THEN PRINT "        "; FLASH 1;"CONGRATULATIONS!": FOR x=1 TO 30: BEEP .01,x: NEXT x
  285 PRINT : PRINT 
  290 PRINT "     The correct word was-",;TAB 15-(LEN g$/2);a$
  300 PRINT 
  310 PRINT "    Want to play again? (y/n)"
  320 IF INKEY$="y" THEN RUN 
  330 GO TO 320
 2000 REM   title
 2010 LET m$=" H A N G C A T ": LET y=8: LET x=((32-LEN m$)/2)
 2020 FOR a=1 TO LEN m$: LET c=15616+(8*(CODE m$(a)-32)): FOR b=0 TO 7: LET d=(USR "a"+(b*2)): POKE d,PEEK (c+b): POKE (d+1),PEEK (c+b): NEXT b: PRINT AT y,x; INVERSE 1;"\a";AT y+1,x;"\b": LET x=x+1: NEXT a
 2030 RETURN 
 9999 SAVE "hangcat" LINE 1: BEEP 1,33