Source Code
10 REM PROGRAM *** "JUMPER"
20 GO SUB 360: LET hi=0
30 GO SUB 320
40 LET v=14: LET h=16: GO SUB 240
50 PRINT AT v,h; PAPER 8;" "
60 LET v=v+(INKEY$="6" AND h<21)-(INKEY$="7" AND v>0)
70 LET h=h+(INKEY$="8" AND h<31)-(INKEY$="5" AND h>0)
80 PRINT AT 4,0; INK 6;a$;AT 11,0;b$;AT 5,0;b$;AT 12,0;a$
90 IF SCREEN$ (v,h)="" THEN GO TO 150
100 PRINT AT v,h; PAPER 8;"\e"
110 LET b$=b$(32)+b$( TO 31)
120 LET a$=a$(2 TO )+a$(1)
130 IF v=2 THEN GO TO 220
140 GO TO 50
150 PRINT AT v,h;"\e"
160 DIM s$(704)
170 PRINT AT 0,0; OVER 1; PAPER 8; INK 2;s$
180 IF ml>0 THEN LET ml=ml-1: GO TO 40
190 IF sc>hi THEN LET hi=sc
200 INPUT "Press ENTER to play again."; LINE b$
210 GO TO 30
220 LET sc=sc+10
230 GO TO 40
240 CLS
250 PRINT 'TAB 12;"HIGH ";hi;TAB 23;"SCORE ";sc' PAPER 1,,
260 PRINT INK 6'a$'b$
270 PRINT ' PAPER 4,,,,
280 PRINT INK 6'b$'a$
290 PRINT ''' PAPER 1,,,,
300 PRINT AT v,h; PAPER 8;"\e"
310 FOR a=1 TO ml: PRINT AT 1,a; INK 5;"\e";: NEXT a: RETURN
320 LET sc=0: BORDER sc: PAPER sc: INK 9: CLS
330 LET a$=" \a\b \a\b \a\b \a\b "
340 LET b$="\c\d \c\d \c\d \c\d \c\d "
350 LET ml=5: RETURN
360 FOR a=0 TO 39
370 READ u: POKE USR "\a"+a,u
380 NEXT a: RETURN
390 DATA 0,1,2,127,235,253,28,8
400 DATA 0,240,16,252,215,187,58,16
410 DATA 0,15,8,63,235,221,28,8
420 DATA 0,128,64,254,203,221,28,8
430 DATA 28,u,8,u,62,8,28,34
440 REM a=\a b=\b c=\c d=\d e=\e
