Planet Finder

Products: Planet Finder
Developer(s): Michael Zerbo
Date: 1984
Type: Program
Platform(s): TS 2068
Tags: Astronomy

Planet Finder is an astronomy tutorial and reference on the Solar System, “© 1984 M. Zerbo” and written by Michael E. Zerbo. It is a collection of astronomical images and information. The main program’s seven-option menu covers: planet information, where you pick up to ten bodies on a drawing of the planets’ orbits and get a page of figures for each with its symbol and a picture; each planet’s satellites; facts about the Moon with a diagram of the lunar phases; the planets’ orbital tilts, drawn as fanned lines from the Sun; a weight simulation that shows what you would weigh on another planet, the Sun or the Moon; and an 80-question multiple-choice test.

The test can be taken in four groups (the terrestrial planets; the gas giants; the Sun, Moon and Pluto; and general information) or all together, with a percentage grade for each group. A right answer plays a rising tune and a wrong one shows the correct answer. In the general information group the answer is always one of the nine planets, chosen from a numbered list.

The tape holds a short loader with a loading screen and two programs. PLANET 1 plays a short tune over an animated title, then offers to load the main program, page through its instructions or review a glossary of astronomy terms; PLANET 2 is the main program.

Program Analysis

Structure (main program)

  • Lines 1–138: set-up, arrays for the test, and user-defined graphics (a filled disc used for the Sun and planets).
  • Lines 140–1642: planet selection on the orbit diagram (keys 0–9, ENTER to choose) and one routine per body, each drawing its symbol with PLOT/DRAW and a filled disc with repeated CIRCLE calls.
  • Lines 2000–2080: title screen and the surface gravity table used by the weight simulation.
  • Lines 3000–3070: main menu; lines 4000–5399: satellites and the test; lines 5400–9998: orbital tilts, the Moon, lunar phases and the weight simulation.
  • Lines 5300 and 5518–5587 hold the test questions and answers, and lines 7000–7092 the planet data, as DATA.

Notable Techniques

  • Wrong answers are generated freshly for each test: many DATA items are expressions such as INT (RND*5000)+4500, which READ evaluates.
  • Line 5399 places the correct answer in a random one of the five slots with boolean arithmetic, LET a=(a1=1)*f2+(a1<>1)*a and so on, and questions already asked are marked in an array so they are not repeated.
  • Menus are dispatched with a computed GO TO, for example GO TO (oo=1)*140+(oo=2)*4000+….
  • Group scores for the combined test are kept by POKEing them into 65268–65271; PLANET 1 also checks 65268 to skip its title when returning from the main program.

Potential Issues

  • In the general information test, an answer outside 1–9 sends line 5200 to GO TO 4415, which re-enters the same check with the same answer; this appears to loop until memory runs out.
  • The weight simulation accepts 0 as a planet number, which reads Mercury’s entry.
  • Choosing “Terminate Program” on either menu prints a goodbye message and then loops on its own line (GO TO 9020, GO TO 5151) until BREAK is pressed; the instructions say to type RUN to start again.

Related Products

Planet Finder is a collection of astronomical images and information. It is a graphically interesting, cleverly designed visual database of solar system facts, celestial bodies and planetary configurations.

Related Articles

AS1 provides functions frequently found only on more expensive software for more expensive computers.

Image Gallery

Source Code

PLANET 1 (menu)
    1 REM PLANET FINDER                   * 1984 M. Zerbo
    2 REM LOAD "PLANET 1"
    5 GO TO 5600
 1000 REM Load Main Program
 1010 INK 7: PRINT AT 16,0;"LOADING": PRINT AT 19,0;"Please wait....";AT 17,0;
 1012 RANDOMIZE USR h: LOAD "planet.B2"
 2000 REM astronomy terms
 2002 CLS : PRINT AT 0,0;"PLANET"'"FINDER"
 2010 PRINT AT 0,16;"Astronomy Terms"
 2020 PRINT : PRINT : PRINT "Albedo: A measure of light      reflection from a planetary     disk."
 2021 PRINT : PRINT "Asteroid: A small rocky object  that orbits the Sun."
 2022 PRINT : PRINT "Axis: an imaginary line around  which a body, such as a planet, rotates."
 2023 PRINT : PRINT "Ecliptic: The plane of Earth's  orbit around the sun."
 2024 PRINT : PRINT "Gas giants: The planets Jupiter,Saturn, Uranus, and Neptune."
 2026 PRINT AT 21,0;"   Press any key to continue    ": PAUSE 0
 2035 FOR f=2 TO 21: PRINT AT f,0;"                                ": NEXT f
 2038 PRINT AT 3,0;"Orbit: The path a planet or     satellite follows as it travels around it's primary.": PRINT 
 2039 PRINT "Orbital Velocity: The speed a   planet or satellite travels in  it's orbit. They are usually    expressed in average figures    since these values are not      constant."
 2040 PRINT : PRINT "Planet: A body of matter of     significant size traveling in   orbit with a star, like the sun,as its primary."
 2052 PRINT AT 19,0;"   Press any key to continue    ": PAUSE 0
 2053 FOR f=2 TO 21: PRINT AT f,0;"                                ": NEXT f
 2054 PRINT AT 3,0;"Phases: The varying shape of thelighted portion of a planet or  moon, such as full, half, etc."
 2055 PRINT : PRINT "Primary: A body of matter which controls the orbital motion of asatellite."
 2056 PRINT : PRINT "Satellite: A moon or man-made   body in orbit around a planet."
 2058 PRINT : PRINT "Solar System: A system of       planetary bodies traveling in   orbit around a star or a system of stars."
 2059 PRINT : PRINT "Terrestrial planets: Mercury,   Venus, Earth and Mars."
 2060 PRINT AT 0,0;: INPUT " Press Enter To Return To Menu  "; LINE a$
 2100 GO TO 9000
 5500 REM TITLE SCREEN
 5600 LET h=CODE "d": BORDER 0: PAPER 0: INK 7
 5602 IF PEEK 65268<>1 THEN GO TO 9000
 5750 GO SUB 8000
 5757 FOR a=0 TO 7
 5758 READ n: POKE USR "q"+a,n: NEXT a
 5759 DATA BIN 00111100
 5760 DATA BIN 01111110
 5761 DATA BIN 11111111
 5762 DATA BIN 11111111
 5763 DATA BIN 11111111
 5764 DATA BIN 11111111
 5765 DATA BIN 01111110
 5766 DATA BIN 00111100
 5768 FOR l=1 TO 25: FOR f=1 TO 10: READ y,z,s,d
 5770 PRINT AT y,z; INK s; PAPER d;"q"
 5771 PAUSE 60: PRINT AT y,z; INK d; PAPER d;" "
 5772 IF INKEY$<>"" AND INKEY$<>" " THEN GO TO 9000
 5773 IF y=8 AND z=19 THEN PAUSE 120
 5774 NEXT f
 5775 RESTORE 5779: NEXT l
 5776 GO TO 9000
 5779 DATA 10,12,7,0,10,14,0,2,10,15,0,2,10,16,0,2
 5780 DATA 10,17,0,2
 5781 DATA 10,19,7,0
 5782 DATA 9,20,7,0,8,19,7,0
 5783 DATA 8,12,7,0,9,11,7,0
 8000 BEEP 1,-20
 8001 BEEP 1,-15
 8002 BEEP 1,-10
 8005 BEEP .25,-3
 8007 BEEP .75,-5
 8010 RETURN 
 8999 REM menu
 9000 POKE 65268,0: PAPER 0: INK 6: CLS : PRINT "    P L A N E T   F I N D E R"
 9001 PRINT AT 21,8;"* 1984 M. Zerbo"
 9002 PRINT AT 2,11;"Written by";AT 3,8;"Michael E. Zerbo"
 9004 PRINT : PRINT : PRINT : PRINT " Options:": PRINT 
 9005 PRINT "(1) Load Main Program"
 9006 PRINT "(2) Review Program Instructions"
 9007 PRINT "(3) Review Astronomy Terms"
 9008 PRINT "(4) Terminate Program"
 9010 PRINT AT 16,0;"Input your choice:": INPUT asd
 9012 IF asd<1 OR asd>4 THEN GO TO 9010
 9015 PRINT AT 8+asd,0;"(";asd;")"
 9016 PAUSE 5: PRINT AT 16,0;"                  "
 9020 PAUSE 25: IF asd=4 THEN PRINT AT 16,0;"Goodbye!!": PRINT #VAL "4": LOAD "ANMATE.B1"
 9025 IF asd=3 THEN GO TO 2000
 9030 IF asd=2 THEN GO TO 9100
 9040 IF asd=1 THEN GO TO 1000
 9090 REM Instructions
 9100 CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,12;"Program Instructions"
 9106 INK 4: PRINT : PRINT 
 9110 PRINT "Planet Finder is a progrm which deals with astronomy education  and can be used both for        reference and as a tutorial on  the Solar System. It can be a   valuable aid in learning about  astronomy."
 9112 PRINT : PRINT "Planet Finder is split into two separate programs. The first    program is the one currently    being used by you now. It deals with instructions on the main   program. It also allows the userto review several astronomy     terms and their definitions."
 9115 PRINT AT 21,0;: GO SUB 9972
 9120 PRINT AT 3,0;
 9122 PRINT "After loading the main program, either through this program or  separately, the title screen    will appear. By pressing any keythe program will begin.": PRINT 
 9125 PRINT "The main menu will immediately  be shown and you will have an   option of 7 selections. The     first option is to review the   planets of our Solar System.    After choosing option #1 you    will be asked the number of     planets you wish to review."
 9130 PRINT AT 16,28;"You"'"have the opportunity to review  all 9 planets and the Sun, so   the highest number you may inputis ten."
 9132 GO SUB 9972
 9135 PRINT AT 3,0;
 9140 PRINT "After giving the number of      planets you wish to review the  screen will clear and a picture of the Solar System will appear along with the circular orbits  of the planets being displayed. The planets are represented by  small circles and are not       displayed in relative sizes."
 9142 PRINT "In the upper right is the word  PLANET and a dash following it. The dash represents the Sun. Thename of the planet you wish to  review will be after the word   PLANET as well. You can choose  the planet you wish to review bypressing the keys 0-9. The key 0repesents the Sun."
 9144 GO SUB 9972
 9145 PRINT AT 3,0;
 9150 PRINT "The keys 1-9 represent the      planets correspondingly. After  the planet you wish to review isdisplayed at the upper right,thepressing of the ENTER key will  allow you to review it. If you  want to review more than one    planet you must first choose allof the planets you wish to      review." 
 9152 PRINT "After choosing the planets,     information about each one will be shown in the order you pickedthem. The picture of the planet will be displayed in the upper  left. The symbol of the planet  along with various information  about them will be given."
 9155 GO SUB 9972
 9160 PRINT AT 3,0;
 9162 PRINT "Along with this information is  temperature data. With several  planets there are special       circumstances accounting for    their temperatures. For Venus   and the gas giants of Jupiter,  Saturn, Uranus & Neptune,the lowextremes are obtained by        temperatures at the cloud tops. Also, the gas giants high       extremes are at the core of the planets."
 9165 PRINT "Option number two on the main   menu displays all of the planetsand their satellites. The name  of each planet is shown and the name of it's satellites         following it."
 9170 GO SUB 9972
 9172 PRINT AT 3,0;
 9175 PRINT "The third option gives          information about our Moon in   a way similiar to option #1."
 9180 PRINT : PRINT "Option number four displays     the planetary orbital tilts. TheSun is shown with the tilts     following it. The name of each  planet is given along with the  number of degrees of it's tilt. The order of the planets        corresponds with the tilt shown next to the Sun."
 9182 PRINT "The fifth section simulates the weights on different planets andthe discrepancy between them dueto gravity."
 9184 PRINT : GO SUB 9972
 9185 PRINT AT 3,0;
 9190 PRINT "By entering the planetary numberof one for Mercury; two for     Venus; three for Earth; four forMars; five for Jupiter; six for Saturn; seven for Uranus; eight for Neptune; nine for Pluto; tenfor the Sun & 11 for the Moon   and then entering the weight on Earth, the weight of the object will be given for both the Earthand the planet you choose. You  could try your own weight on    Earth and ";
 9192 PRINT "see what you would    weigh on other planets.": PRINT 
 9195 PRINT : PRINT : GO SUB 9972
 9205 PRINT AT 3,0;"The sixth section is a multiple choice test on the Solar System.It contains 80 questions and canbe taken in groups dealing with different aspects of the Solar  System."
 9210 PRINT : PRINT "The different groups provided   are: The terrestial planets     (4 inner) , The gas giants, The Sun,Moon & Pluto, and a General Information group."
 9212 PRINT "You are also able to take all 4 groups at once. A grade on each section is given at the end of  the test."
 9214 PRINT : PRINT : GO SUB 9972
 9220 PRINT AT 3,0;"During the test you are given 5 answers to choose from. You are to input the number you want foryour answer. If you are correct a tune will be sounded and if   you are wrong the correct answerwill be given along with a      different tune being played."
 9222 PRINT : PRINT "Basically the general           information section is the      easiest of the 4 groups. This isbecause instead of 5 answers to choose from you have all 9      planets to make your choice     with."
 9223 PRINT : GO SUB 9972
 9230 PRINT AT 3,0;"The general information section gives questions about the       planets and the answers to thesequestions is one of the planets in our Solar System. After      entering the number representinga planet a response will be     given in a similar woy as the   other groups."
 9232 PRINT "However, in response to an      incorrect answer the planet     which represents a correct      answer will have a yellow markernext to it. Your wrong answer   will be marked in white. After  taking the test you will be     graded in the same way as the   other sections."
 9234 GO SUB 9972
 9235 PRINT AT 3,0;"Every time you take a test the  answers you can choose from willbe different. Also the placementof the correct answer will      change with every test you take.In the terrestial planet        section, which contains the mostquestions, the order of the     questions will be different     after each test. These changes  that occur in each test are for all the sections excluding the  general information group."
 9236 PRINT : PRINT : GO SUB 9972
 9237 PRINT AT 3,0;"These changes are put in place  so each time you take a test it will be more challenging. Also  don't be discouraged if you do  badly at first. Some of the     questions are very hard and if  you aren't an expert in         astronomy it is expected of you to get low grades at first. By  reviewing the information in    different parts of the program  and taking careful considerationof the questions you get wrong, you will be most likely to get ahigher grade in the future."
 9238 PRINT : PRINT : GO SUB 9972
 9240 PRINT AT 3,0;"The last choice of the main menuis to terminate the program. Theprogram will be ended and by    typing RUN it will allow you to start the program again."
 9300 PRINT : PRINT : PRINT "  (Press any key to continue)"
 9302 PAUSE 0: BEEP .05,31
 9949 GO TO 9000
 9972 PRINT "  (Press any key to continue)"
 9975 PAUSE 0: BEEP .05,31: CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,12;"Program Instructions"
 9976 RETURN 
 9992 RANDOMIZE USR 100: SAVE "planet.B1" LINE 1
 9998 RANDOMIZE USR 100: LOAD "L.B1"

PLANET 2 (main program)
    1 REM PLANET FINDER                   * 1984 M. Zerbo
    2 REM  Load "PLANET 2"
    3 REM :Astronomy Education
    4 GO SUB 2000: RESTORE 86
    5 DIM q(10): DIM a(4): DIM b(4)
    6 LET a(1)=10: LET a(2)=8: LET a(3)=5: LET a(4)=9
    7 LET b(1)=5516: LET b(2)=5536: LET b(3)=5552: LET b(4)=5562
    8 PAPER 0: INK 7: BORDER 0: CLS 
   80 FOR f=0 TO 7
   82 READ a
   84 POKE USR "q"+f,a: NEXT f
   86 DATA BIN 00111100
   87 DATA BIN 01111110
   88 DATA BIN 11111111
   89 DATA BIN 11111111
   90 DATA BIN 11111111
   91 DATA BIN 11111111
   92 DATA BIN 01111110
   93 DATA BIN 00111100
  100 FOR e=0 TO 7
  101 READ s
  102 POKE USR "a"+e,s: NEXT e
  103 DATA BIN 01110000
  104 DATA BIN 01110000
  105 DATA BIN 00000000
  106 DATA BIN 00000000
  107 DATA BIN 00000000
  108 DATA BIN 00000000
  109 DATA BIN 00000000
  110 DATA BIN 00000000
  138 GO TO 3000
  140 REM PLANET INFORMATION
  142 CLS : PRINT AT 0,0;"PLANET"'"FINDER"
  150 PRINT AT 0,20;"SOLAR SYSTEM"
  152 PRINT AT 1,18;"PLANET:  -"
  155 PRINT AT 5,21;"Our solar"'TAB 21;"system is"
  156 PRINT AT 7,21;"aprox. 4.6"'TAB 21;"billion yrs"
  157 PRINT AT 9,22;"old."
  158 FOR f=11 TO 15: PRINT AT f,22;"..........": NEXT f
  160 PRINT AT 17,20;"Keys 0-9"
  162 PRINT TAB 19;"choose planet"
  170 PRINT AT 20,19;"Press ""M"" to"'TAB 20;"go to menu"
  200 PRINT INK 6;AT 10,11;"q"
  202 CIRCLE 91,91,12
  206 CIRCLE 91,91,18
  208 CIRCLE 91,91,24
  209 CIRCLE 91,91,29
  210 CIRCLE 91,91,45
  211 CIRCLE 91,91,55
  212 CIRCLE 91,91,65
  214 CIRCLE 91,91,75
  215 CIRCLE 85,82,80
  220 CIRCLE 91,103,2: BEEP .005,1
  222 CIRCLE 75,97,2: BEEP .005,1
  225 CIRCLE 68,91,2: BEEP .005,1
  226 CIRCLE 64,82,2: BEEP .005,1
  228 CIRCLE 47,91,2: BEEP .005,1
  229 CIRCLE 146,91,2: BEEP .005,1
  230 CIRCLE 91,26,2: BEEP .005,1
  231 CIRCLE 95,161,2: BEEP .005,1
  232 CIRCLE 143,146,2: BEEP .005,1
  350 LET rr=48
  400 FOR f=1 TO b
  401 LET w=CODE INKEY$
  402 IF w=109 OR w=77 THEN CLS : GO TO 3000
  403 GO SUB 410
  404 IF w=13 THEN GO TO 420
  406 GO TO 401
  410 GO SUB 500+rr
  411 IF w<48 OR w>57 THEN RETURN 
  412 LET rr=w
  414 RETURN 
  420 BEEP .05,1: PAUSE 20: LET q(f)=rr
  422 NEXT f
  430 FOR x=1 TO b
  432 GO SUB 600+((q(x)-47)*100): NEXT x
  435 CLS : GO TO 3000
  548 PRINT AT 1,25;"  -    ": RETURN 
  549 PRINT AT 1,25;"Mercury": RETURN 
  550 PRINT AT 1,25;"Venus  ": RETURN 
  551 PRINT AT 1,25;"Earth  ": RETURN 
  552 PRINT AT 1,25;"Mars   ": RETURN 
  553 PRINT AT 1,25;"Jupiter": RETURN 
  554 PRINT AT 1,25;"Saturn ": RETURN 
  555 PRINT AT 1,25;"Uranus ": RETURN 
  556 PRINT AT 1,25;"Neptune": RETURN 
  557 PRINT AT 1,25;"Pluto  ": RETURN 
  700 CLS : PRINT TAB 14;"SUN"
  720 PRINT AT 3,11;"Symbol:"
  722 CIRCLE 150,148,3
  725 PLOT 150,148
  727 PRINT : PRINT "________________________________": PRINT 
  730 PRINT "Distance to nearest"'"star: 4.3 light years"
  732 PRINT "Rotation: 25d 8h 24m E"
  734 PRINT "Axis tilt: 7.25 degrees"
  735 PRINT "Diameter: 865,000 miles"'"1,392,000km;  (Earth=1):109"
  737 PRINT "Mass relative to Earth: 332,946"
  738 PRINT "Volume relative to Earth:1300000"
  740 PRINT "Mean density: 1.41"
  742 PRINT "Surface gravity (Earth=1): 27.8"
  743 GO SUB 750: FOR f=7 TO 21: PRINT AT f,0;"                                ": NEXT f: PRINT AT 7,0;"              High  15E+6 deg. C"
  744 PRINT "Temperature } Low   6,000 deg. C"
  745 PRINT "Extremes      High  27E+6 deg. F"
  746 PRINT "              Low  10,800 deg. F"
  748 PRINT : PRINT "   Press any key to continue    "
  749 PAUSE 0: RETURN 
  750 PRINT "Oblateness: 0"
  752 PRINT "Satellites: 9 planets"
  758 PRINT "Atmosphere(Principal gases):H2                              He"
  759 PRINT AT 21,0;"                                "
  760 INK 6: PLOT 24,152: DRAW 22,22,777: INK 7
  761 PRINT AT 21,0;"   Press any key to continue   "
  762 PAUSE 0: RETURN 
  800 CLS : PRINT TAB 12;"MERCURY"
  815 PRINT AT 3,11;"Symbol:"
  820 CIRCLE 151,150,3
  821 DRAW 0,2: DRAW -2,2: DRAW 2,2: DRAW -2,-2: DRAW -2,0: DRAW -2,2
  822 DRAW 2,-2: DRAW -2,-2: DRAW 0,-2: DRAW 2,-2: DRAW 1,0: DRAW 0,-2: DRAW -2,0: DRAW 4,0
  823 DRAW -2,0: DRAW 0,-2: RESTORE 7000
  824 GO SUB 826: FOR f=1 TO 10: CIRCLE INK 1;24,152,f: NEXT f: GO TO 856
  826 READ p$,q$,r$,s$,t$,u$,v$,w$,x$,y$,z$,a$: PRINT : PRINT "________________________________"
  830 PRINT : PRINT "Average distance": PRINT "from sun:";
  832 PRINT " ";p$
  835 PRINT "          ";q$
  836 PRINT "          ";r$
  838 PRINT "Revolution: ";s$
  839 PRINT "Rotation: ";t$
  840 PRINT "Average orbital speed: ";u$
  842 PRINT "Axis tilt: ";v$
  848 PRINT "Diameter: ";w$
  849 PRINT "          ";x$
  850 PRINT "Mass relative to Earth: ";y$
  852 PRINT "Volume relative to Earth: ";z$
  854 PRINT "Mean density: ";a$
  855 PRINT AT 21,0;"                                ": RETURN 
  856 PRINT AT 21,0;"   Press any key to continue    "
  858 PAUSE 0
  860 FOR f=7 TO 21: PRINT AT f,0;"                                ": NEXT f
  861 READ p$,q$,r$,s$,t$,u$,v$,w$,x$,y$
  862 PRINT AT 7,0;"Surface gravity (Earth=1): ";p$
  864 PRINT "Eccentricity of orbit: ";q$
  865 PRINT "Albedo (light reflection): ";r$
  866 PRINT "Oblateness of planet: ";s$
  867 PRINT : PRINT t$
  868 PRINT "Temperature }";u$
  869 PRINT "Extremes";v$
  870 PRINT w$
  872 PRINT : PRINT "Known satellites: ";x$
  873 PRINT "Atmosphere(Principal gases):";y$
  875 PRINT : PRINT "   Press any key to continue    "
  876 PAUSE 0
  880 RETURN 
  899 STOP 
  900 CLS : PRINT TAB 13;"VENUS"
  915 PRINT AT 3,11;"Symbol:"
  920 CIRCLE 150,151,3
  922 DRAW -2,-2: DRAW -1,0
  923 DRAW 0,-2: DRAW -2,0: DRAW 4,0
  925 DRAW -2,0: DRAW 0,-2
  930 RESTORE 7020: GO SUB 826
  931 FOR f=1 TO 12: CIRCLE INK 6;24,152,f: NEXT f
  932 GO TO 856
  950 STOP 
 1000 CLS : PRINT TAB 13;"EARTH"
 1015 PRINT AT 3,11;"Symbol:"
 1020 CIRCLE 150,148,4: DRAW 0,2: DRAW -6,0:
 1022 PLOT 151,151: DRAW 0,-6
 1023 RESTORE 7030: GO SUB 826
 1025 FOR f=1 TO 13: CIRCLE INK 5;24,152,f: NEXT f
 1026 GO TO 856
 1050 STOP 
 1100 CLS : PRINT TAB 14;"MARS"
 1115 PRINT AT 3,11;"Symbol:"
 1116 CIRCLE 150,148,3: DRAW 0,2: DRAW -1,1: DRAW 5,5
 1118 DRAW -3,0: DRAW 4,0: DRAW 0,-3
 1120 RESTORE 7040: GO SUB 826
 1122 FOR f=1 TO 11: CIRCLE INK 2;24,152,f: NEXT f
 1123 GO TO 856
 1150 STOP 
 1200 CLS : PRINT TAB 12;"JUPITER"
 1255 PRINT AT 3,11;"Symbol:2": PLOT 150,145: DRAW 4,0: DRAW 0,3: DRAW 0,-4: DRAW 0,1: DRAW 2,0
 1260 RESTORE 7050: GO SUB 826
 1262 FOR f=1 TO 14: CIRCLE INK 3;24,152,f: NEXT f
 1263 PRINT AT 3,2;"q":
 1265 GO TO 856
 1280 STOP 
 1300 CLS : PRINT TAB 12;"SATURN"
 1310 CIRCLE 24,155,11
 1314 LET a=21: LET b=165
 1315 FOR l=1 TO 2: PLOT a,b: DRAW -8,8: DRAW -3,0: DRAW 6,-10: DRAW 18,-18
 1316 DRAW 7,-7: DRAW 2,0: DRAW -2,5: DRAW -6,6
 1317 LET a=20: LET b=165: NEXT l
 1320 PRINT AT 3,11;"Symbol:": PLOT 148,156: DRAW 0,-2: DRAW -2,0: DRAW 4,0: DRAW -2,0: DRAW 0,-4: DRAW 2,0
 1322 DRAW 0,1: DRAW 2,2: DRAW 3,0: DRAW 2,-2: DRAW 0,-2: DRAW -3,-3: DRAW 0,-2
 1330 RESTORE 7060: GO SUB 826: GO TO 856
 1350 STOP 
 1400 CLS : PRINT TAB 13;"URANUS"
 1430 PRINT AT 3,11;"Symbol:"
 1432 CIRCLE 150,148,3: DRAW 0,2: DRAW -2,2: DRAW -1,0: DRAW 0,6: DRAW -2,-2: DRAW 2,2: DRAW 2,-2: PLOT 150,148
 1440 RESTORE 7070: GO SUB 826
 1445 FOR f=1 TO 13: CIRCLE INK 4;24,152,f: NEXT f
 1446 GO TO 856
 1450 STOP 
 1500 CLS : PRINT TAB 12;"NEPTUNE"
 1530 PRINT AT 3,11;"Symbol:"
 1532 PLOT 150,144: DRAW 0,3: DRAW -3,0: DRAW 6,0: DRAW -3,0: DRAW 0,8: DRAW -1,-1: DRAW 1,1: DRAW 1,-1
 1540 PLOT 150,150: DRAW -4,0: DRAW -1,1: DRAW 0,4: DRAW -1,-1: DRAW 1,1: DRAW 1,-1
 1545 PLOT 150,150: DRAW 4,0: DRAW 1,1: DRAW 0,4: DRAW -1,-1: DRAW 1,1: DRAW 1,-1
 1546 RESTORE 7080: GO SUB 826
 1548 FOR f=1 TO 13: CIRCLE INK 1;24,152,f: NEXT f
 1549 GO TO 856
 1550 STOP 
 1600 CLS : PRINT TAB 13;"PLUTO"
 1630 PRINT AT 3,11;"Symbol:P": PLOT 144,150: PLOT 145,145: DRAW 0,-2: DRAW 3,0
 1635 RESTORE 7090: GO SUB 826
 1640 FOR f=1 TO 9: CIRCLE INK 1;24,152,f: NEXT f
 1642 GO TO 856
 2000 BORDER 1: INK 7: PAPER 0: CLS 
 2002 PRINT AT 0,0;: PRINT "    //// /  /// /  / //// //////"
 2005 PRINT "   /  / /  / / // / /       /"
 2006 PRINT "  //// /  /// / // ////    /"
 2007 PRINT " /    /  / / /  / /       /"
 2009 PRINT "/    // / / /  / ////    /"
 2010 PRINT : PRINT : PRINT "        F  I  N  D  E  R"
 2023 PRINT AT 10,15;"__"
 2024 PRINT AT 11,14;"____"
 2025 PRINT AT 12,13;"______"
 2026 PRINT AT 13,13;"______"
 2027 PRINT AT 14,14;"____"
 2028 PRINT AT 15,15;"__"
 2030 PRINT AT 21,0;"                                "
 2031 PRINT AT 18,1;"Planet Finder  * 1984 M. Zerbo"
 2032 PRINT AT 19,4;"Written by Michael Zerbo"       
 2065 PAUSE 250
 2067 PRINT AT 20,0;"    (Press any key to begin)    "
 2068 PAUSE 20: IF INKEY$="" THEN GO TO 2068
 2069 BEEP .02,22: RETURN 
 2070 DATA "Mercury",.38
 2071 DATA "Venus",.9
 2072 DATA "Earth",1
 2073 DATA "Mars",.38
 2074 DATA "Jupiter",2.87
 2075 DATA "Saturn",1.32
 2076 DATA "Uranus",.93
 2077 DATA "Neptune",1.23
 2078 DATA "Pluto ?",.03
 2079 DATA "Sun",27.8
 2080 DATA "Moon",.16
 3000 REM ***Main Menu***
 3002 PRINT "    P L A N E T  F I N D E R"    
 3010 PRINT : PRINT : PRINT "          ***********"'"          *Main Menu*"'"          ***********"
 3020 PRINT : PRINT : PRINT "(1) Review planet information"
 3022 PRINT "(2) Planets & their Satellites"
 3025 PRINT "(3) Facts about The Moon"'"(4) Planetary orbital tilts"
 3030 PRINT "(5) Weight simulation"
 3040 PRINT "(6) Questions about the "'"    Solar System"
 3052 PRINT "(7) Terminate program"
 3059 INPUT oo
 3060 IF oo<1 OR oo>7 THEN GO TO 3059
 3061 IF oo>6 THEN PRINT AT oo+8,0;"(";oo;")": GO TO 3063
 3062 PRINT AT oo+7,0;"(";oo;")"
 3063 IF oo<>1 THEN GO TO 3070
 3064 PAUSE 5: INPUT "Input number of planets you wishto review:  ";b
 3065 IF b<0 OR b>10 THEN GO TO 3064
 3070 PAUSE 12: GO TO (oo=1)*140+(oo=2)*4000+(oo=4)*5400+(oo=3)*6000+(oo=5)*9060+(oo=6)*4075+(oo=7)*5150
 4000 REM Satellites
 4001 CLS : PRINT AT 0,0;"PLANET"'"FINDER"
 4002 PRINT AT 0,20;"SATELLITES"
 4010 PRINT : PRINT : PRINT "MERCURY: n/a"
 4020 PRINT "VENUS: n/a"
 4025 PRINT "EARTH: Moon"
 4030 PRINT "MARS: Phobos,Deimos"
 4032 PRINT "JUPITER: 1979 J-3,Adrastea,"'"Amalthea,1979 J-2,Io,Europa,"'"Ganymede,Callisto,Leda,Himalia,"'"Lysithea,Elara,Ananke,Carme,"'"Pasiphae,Sinope"
 4040 PRINT "SATURN: 1980 S-28,1980 S-27,1980S-26,1980 S-1,1980 S-3,Mimas,"'"Enceladus,Tethys,Tethys B,"'"Tethys C,Dione,Dione B,Rhea,"'"Titan,Hyperion,Iapetus,Phoebe"
 4050 PRINT "URANUS: Miranda,Ariel,Umbrial   Titania,Oberon"
 4055 PRINT "NEPTUNE: Triton,Nereid"
 4056 PRINT "PLUTO: Charon"
 4060 PRINT " Press Any Key To Return To Menu": PAUSE 0
 4062 CLS : GO TO 3000
 4075 LET ss=0: LET gg=0: LET wr=0: LET e=109991: LET h=119999: CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,15;"Solar System Test"
 4078 PRINT AT 5,12;"MENU"
 4080 PRINT : PRINT "(1) The Terrestial Planets"'"(2) The Gas Giants"'"(3) The Sun,Moon & Pluto"'"(4) General Information"
 4081 PRINT "(5) All of the above"
 4083 INPUT "Input your choice (1 to 5) ";c1
 4085 IF c1>5 OR c1<1 THEN GO TO 4083
 4086 FOR f=2 TO 12: PRINT AT f,0;"                                ": NEXT f
 4088 BEEP .05,11: IF c1=5 THEN FOR p=1 TO 5: GO TO (p=1)*4090+(p=2)*4115+(p=3)*4200+(p=4)*4400+(p=5)*5000
 4089 GO TO (c1=1)*4090+(c1=2)*4115+(c1=3)*4200+(c1=4)*4400
 4090 PRINT AT 3,4;"THE TERRESTIAL PLANETS"
 4091 DIM s(20): PRINT 
 4092 FOR v=1 TO 4: FOR i=1 TO a(v): LET wr=wr+1: PRINT "Question #";wr
 4093 LET f1=INT (RND*a(v))+1: LET ff=(f1*2)+b(v): IF s(f1)=1 THEN GO TO 4093
 4094 LET s(f1)=1: LET a1=INT (RND*5)+1: RESTORE ff: READ a$,k$,a,b,c,d,e,f2: GO SUB 5399: GO SUB 4095: GO TO 4102
 4095 IF a$<>"" THEN PRINT : PRINT a$: LET llk=8: PRINT : IF LEN a$>32 THEN LET llk=9
 4097 PRINT "(1) ";a;" ";k$'"(2) ";b;" ";k$'"(3) ";c;" ";k$'"(4) ";d;" ";k$'"(5) ";e;" ";k$
 4098 INPUT aa: IF aa>=1 AND aa<=5 THEN PRINT AT llk+aa,0;"(";aa;")": PAUSE 20: PRINT AT llk+6,0;
 4099 IF aa=a1 THEN PRINT : PRINT "CORRECT!!!": FOR f=11 TO 15: BEEP .05,f: NEXT f: PRINT : LET gg=gg+1
 4100 IF aa<>a1 THEN PRINT : PRINT "WRONG!!!": FOR f=3 TO 1 STEP -1: BEEP .1,f: NEXT f: PRINT : PRINT "The answer was ";f2;" ";k$
 4101 PRINT : PRINT "(Press any key to continue)": PAUSE 0: RETURN 
 4102 CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,15;"Solar System Test"
 4103 PRINT AT 3,4;"THE TERRESTIAL PLANETS": PRINT 
 4104 NEXT i: FOR f=1 TO a(v): LET s(f)=0: NEXT f: NEXT v: LET wy=wr
 4105 PRINT "Grade:";INT ((gg*100/wy)+.50000001);"% Correct"
 4106 PRINT : PRINT "Out of ";wy;" questions you got ";gg'"correct and ";wy-gg;" wrong."
 4108 PRINT : IF gg=wy THEN PRINT "Congratulations on a perfect    score!"
 4109 IF c1=5 THEN POKE 65267+p,INT ((gg*100/wy)+.50000001): LET wy=0: LET ss=ss+gg: PRINT AT 19,0;"Press any key to continue:": LET gg=0: PAUSE 0: FOR f=2 TO 21: PRINT AT f,0;"                                ": NEXT f: NEXT p
 4110 LET wy=0: LET gg=0: PRINT AT 20,0;"Press ""M"" to return to Main Menu"'"Press ""Q"" to go to Test Menu"
 4111 IF INKEY$="m" OR INKEY$="M" THEN CLS : GO TO 3000
 4112 IF INKEY$="q" OR INKEY$="Q" THEN CLS : GO TO 4075
 4113 GO TO 4111
 4115 LET wew=1: PRINT AT 3,9;"THE GAS GIANTS"
 4116 PRINT : FOR w=1 TO 4: PRINT "Question #";wew
 4117 LET a$="": RESTORE (5581+w): READ o$,f2,k$
 4120 LET llk=8: PRINT : PRINT "What is the diameter of ";o$;"?": PRINT 
 4121 LET a1=INT (RND*5)+1: LET a=INT (RND*13000)+15000
 4122 LET b=55200: LET c=7927: LET d=INT (RND*30000)+93000: LET e=INT (RND*10000)+10000
 4123 GO SUB 4180: GO SUB 4178
 4124 LET llk=9: PRINT : PRINT "What is the period of orbit for ";o$;"?": PRINT 
 4125 LET a=INT (RND*5)+4: LET b=18.12: LET c=39.2: LET d=INT (RND*100)+180: LET e=INT (RND*25)+100
 4126 GO SUB 4179: GO SUB 4178
 4127 PRINT : PRINT "What is the period of rotation  for ";o$;"?": PRINT 
 4128 LET a=INT (RND*4)+4.2: LET b=44.12: LET c=13: LET d=INT (RND*10)+20: LET e=100.52: GO SUB 4179
 4130 GO SUB 4178: PRINT : PRINT "What is the average orbital     speed of ";o$;"?": PRINT 
 4131 LET a=INT (RND*20)+15: LET b=27.72: LET c=INT (RND*2)+1.2: LET d=11.81: LET e=INT (RND*50)+16: GO SUB 4179
 4143 GO SUB 4178: PRINT : PRINT "What is the average distance"'o$;" is from the sun?"
 4144 PRINT : LET a=93000000: LET b=INT (RND*100000000)+150000000: LET c=222870000: LET d=654000000: LET e=989000000: GO SUB 4179
 4145 PRINT : LET wew=wew+1: NEXT w
 4150 GO SUB 4184: PRINT : LET wy=wew-1: LET wew=0: GO TO 4105
 4178 PRINT : LET a1=INT (RND*5)+1: LET wew=wew+1: PRINT "Question #";wew: RETURN 
 4179 READ f2,k$
 4180 GO SUB 5399
 4182 GO SUB 4095
 4184 CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,15;"Solar System Test"
 4185 PRINT AT 3,9;"THE GAS GIANTS"
 4186 RETURN 
 4200 PRINT AT 3,6;"THE SUN,MOON & PLUTO"
 4202 PRINT : LET w=1: PRINT "Question #";w
 4205 LET a$="What is the average distance    Pluto is from the sun?"
 4206 LET k$="miles": LET a1=INT (RND*5)+1
 4207 LET a=INT (RND*93000000)+100000000: LET b=INT (RND*100000000)+150000000: LET c=222870000: LET d=1654000000: LET e=2989000000: LET f2=3666000000: GO SUB 5399
 4208 GO SUB 4095: GO SUB 4280
 4210 LET k$="Earth years": LET a$="What is the period of orbit for Pluto?"
 4212 LET a=INT (RND*5)+54: LET b=98.12: LET c=209.2: LET d=INT (RND*100)+100: LET e=INT (RND*25)+100: LET f2=247.7
 4214 GO SUB 5399: GO SUB 4095
 4215 GO SUB 4280: LET a$="What is the period of rotation  for Pluto?": LET k$="days"
 4216 LET f2=6.40: LET a=INT (RND*19)+15.2: LET b=44.12: LET c=13: LET d=INT (RND*10)+20: LET e=1.52
 4217 GO SUB 5399: GO SUB 4095: GO SUB 4280
 4220 LET k$="km/sec.": LET a$="What is the average orbital     speed of Pluto?"
 4222 LET a=INT (RND*20)+15: LET b=17.72: LET c=INT (RND*2)+1.2: LET d=11.81: LET e=INT (RND*50)+16: LET f2=4.7
 4223 GO SUB 5399: GO SUB 4095
 4224 GO SUB 4280
 4225 LET k$="": LET a$="How many satellites does Pluto   have?"
 4226 LET a=INT (RND*5)+3: LET b=INT (RND*10)+2: LET c=INT (RND*10)+8: LET d=5: LET e=0: LET f2=1
 4227 GO SUB 5399: GO SUB 4095
 4230 GO SUB 4280
 4232 LET a$="What is the average distance theMoon is from the Earth?": LET k$="km"
 4234 LET a=INT (RND*300000)+450000: LET b=INT (RND*700000)+700000: LET c=INT (RND*80000)+100000: LET d=297210: LET e=INT (RND*200000)+500000: LET f2=384000
 4235 GO SUB 5399: GO SUB 4095: GO SUB 4280
 4236 LET a$="What is the escape velocity for the Moon?": LET k$="miles/hour"
 4238 LET a=INT (RND*3000)+1000: LET b=8722: LET c=INT (RND*10000)+6000: LET d=13012: LET e=INT (RND*5000)+7500: LET f2=5324
 4240 GO SUB 5399: GO SUB 4095: GO SUB 4280
 4241 LET a$="How long is the Moon's          revolution around the Earth?": LET k$="days"
 4242 LET a=INT (RND*10)+12.2: LET b=INT (RND*25)+45: LET c=11.8: LET d=3.4: LET e=32: LET f2=27.3
 4243 GO SUB 5399: GO SUB 4095: GO SUB 4280
 4244 FOR y=1 TO 2
 4245 RESTORE (y+5585)
 4246 READ o$,k$,f2
 4247 LET a$="What is the diameter of the     "+o$+"?"
 4248 IF o$="Sun" THEN GO TO 4250
 4249 LET a=1850: LET b=5320: LET c=INT (RND*5000)+4000: LET d=INT (RND*10000)+9000: LET e=INT (RND*1000)+1: GO TO 4252
 4250 LET a=INT (RND*300000)+300000:: LET b=95320: LET c=INT (RND*500000)+250000: LET d=3180000: LET e=INT (RND*100000)+1
 4252 GO SUB 5399: GO SUB 4095: GO SUB 4280
 4253 READ k$,f2
 4254 LET a$="What is the surface gravity of  the "+o$+"?"
 4255 IF o$="Sun" THEN GO TO 4257
 4256 LET a=1.12: LET b=0.10: LET c=.02: LET d=0.91: LET e=2.21: GO TO 4258
 4257 LET a=15.2: LET b=4.5: LET c=INT (RND*10)+10.22: LET d=212.15: LET e=97.75
 4258 GO SUB 5399: GO SUB 4095: GO SUB 4280
 4259 READ k$,f2: LET a$="What is the "+o$+"'s mass?:Earth=1"
 4260 IF o$="Sun" THEN GO TO 4262
 4261 LET a=.05: LET b=INT (RND*3)+1.12: LET c=.15: LET d=.98: LET e=1.54: GO TO 4263
 4262 LET a=INT (RND*59000)+200000: LET b=INT (RND*120000)+100000: LET c=5000.2: LET d=798.72: LET e=5550.54
 4263 GO SUB 5399: GO SUB 4095: GO SUB 4280: NEXT y
 4265 LET wy=w: LET w=0
 4266 PRINT : GO TO 4105
 4280 LET a1=INT (RND*5)+1: CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,15;"Solar System Test"
 4282 PRINT AT 3,6;"THE SUN,MOON & PLUTO"
 4283 IF w=14 THEN RETURN 
 4284 LET w=w+1: PRINT : PRINT "Question #";w
 4285 RETURN 
 4400: CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,15;"Solar System Test"
 4401 LET ju=0
 4402 PRINT AT 3,6;"GENERAL INFORMATION"
 4403 RESTORE 5300
 4405 PRINT 
 4406 PRINT : PRINT " PLANETS"
 4408 GO SUB 4410: GO TO 4412
 4410 LET ju=ju+1: PRINT AT 9,0;"(1) Earth"'"(2) Jupiter"'"(3) Pluto"'"(4) Mars"'"(5) Saturn"'"(6) Mercury"'"(7) Neptune"'"(8) Venus"'"(9) Uranus"
 4411 PRINT AT 9,17;"Question #";ju: RETURN 
 4413 INPUT "Which of the planets has the    hottest surface temperature? ";aa: GO SUB 4416: GO TO 4430
 4416 GO SUB 5200: READ f2
 4419 IF aa=f2 THEN : FOR f=11 TO 15: BEEP .05,f: NEXT f: LET gg=gg+1
 4420 IF aa=f2 THEN INPUT "CORRECT!! (Press enter to cont.)";a$
 4422 IF aa<>f2 THEN : FOR f=3 TO 1 STEP -1: BEEP .1,f: NEXT f: PRINT AT 8+f2,0;"(";f2;")"
 4423 IF aa<>f2 THEN INPUT "WRONG!! (Press enter to cont.)  ";a$
 4425 RETURN 
 4430 GO SUB 4410: INPUT "What planet is literally on it'sside? ";aa
 4431 GO SUB 4415
 4432 GO SUB 4410: INPUT "Which Planet has the most moons?";aa
 4433 GO SUB 4415
 4435 GO SUB 4410: INPUT "Which Planet has the smallest   diameter? ";aa: GO SUB 4415
 4437 GO SUB 4410: INPUT "Which planet has the largest    diameter? ";aa: GO SUB 4415
 4438 GO SUB 4410: INPUT "Which Planet has a moon the mostsimilar in size with itself? ";aa: GO SUB 4415
 4439 GO SUB 4410: INPUT "Which Planet has polar ice caps made up of frozen carbon dioxideand frozen water? ";aa: GO SUB 4415
 4440 GO SUB 4410: INPUT "Which Planet has the largest    moon (Titan)? ";aa: GO SUB 4415
 4441 GO SUB 4410: INPUT "Which Planet has the only moon  with an atmosphere? ";aa: GO SUB 4415
 4442 GO SUB 4410: INPUT "Which planet occasionally lies  outside Pluto's orbit making it the planet farthest from the    Sun? ";aa: GO SUB 4415
 4443 GO SUB 4410: INPUT "Which planet's diameter is most like the Earth's? ";aa: GO SUB 4415
 4445 GO SUB 4410: INPUT "Which planet other than possiblyPluto is less dense than water? ";aa: GO SUB 4415
 4446 GO SUB 4410: INPUT "Which planet is closest to the  Sun? ";aa: GO SUB 4415
 4447 GO SUB 4410: INPUT "Which planet is closest to the  Earth? ";aa: GO SUB 4415
 4450: CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,15;"Solar System Test"
 4452 PRINT AT 3,6;"GENERAL INFORMATION"
 4454 LET wy=ju: LET ju=0: PRINT : GO TO 4105
 5000 CLS : PRINT AT 0,0;"PLANET"'"FINDER": PRINT AT 0,15;"Solar System Test"
 5002 PRINT : PRINT : PRINT TAB 12;"GRADE"
 5005 PRINT : PRINT "The Terrestial Planets:";PEEK 65268;"%"
 5006 PRINT : PRINT "The Gas Giants:";PEEK 65269;"%"
 5007 PRINT : PRINT "The Sun,Moon & Pluto:";PEEK 65270;"%"
 5008 PRINT : PRINT "General Information:";PEEK 65271;"%"
 5009 PRINT "________________________________": PRINT 
 5010 PRINT "Total:";INT ((ss*100/80)+.50000001);"% Correct"
 5020 PRINT : PRINT "Out of 80 questions you got ";ss;'"correct and ";80-ss;" wrong."
 5050 PRINT : IF ss=80 THEN PRINT "Congratulations on a perfect    score!"
 5099 FOR f=65268 TO 65271: POKE f,0: NEXT f: LET ss=0: GO TO 4110
 5150 PRINT : PRINT : PRINT "Well then, Goodbye."
 5151 PRINT #VAL "4": LOAD "L.B1"
 5200 IF aa<1 OR aa>9 THEN GO TO 4415
 5201 PRINT AT 8+aa,0;"(";aa;")": RETURN 
 5300 DATA 8,9,5,3,2,3,4,5,5,7,8,5,6,8
 5398 STOP 
 5399 LET a=(a1=1)*f2+(a1<>1)*a: LET b=(a1=2)*f2+(a1<>2)*b: LET c=(a1=3)*f2+(a1<>3)*c: LET d=(a1=4)*f2+(a1<>4)*d: LET e=(a1=5)*f2+(a1<>5)*e: RETURN 
 5400 CLS : PRINT AT 0,0;"PLANET"'"FINDER"
 5402 PRINT AT 0,19;"Orbital Tilts"
 5405 PRINT AT 15,11;"q": PRINT AT 17,10;"SUN"
 5408 PLOT 98,48: DRAW 150,0
 5410 PLOT 98,48: DRAW 150,2
 5420 PLOT 98,48: DRAW 150,4
 5422 PLOT 98,48: DRAW 150,6
 5423 PLOT 98,48: DRAW 150,8
 5424 PLOT 98,48: DRAW 150,10
 5425 PLOT 98,48: DRAW 150,15
 5426 PLOT 98,48: DRAW 150,28
 5427 PLOT 98,48: DRAW 150,68
 5500 PRINT AT 3,0;"Pluto 17.2 Degrees"
 5502 PRINT "Mercury 7 Degrees"
 5504 PRINT "Venus 3.4 Degrees"
 5505 PRINT "Saturn 2.5 Degrees"
 5506 PRINT "Mars 1.9 Degrees"
 5508 PRINT "Neptune 1.8 Degrees"
 5509 PRINT "Jupiter 1.3 Degrees"
 5510 PRINT "Uranus .8 Degrees"
 5511 PRINT "Earth 0 Degrees"
 5515 PRINT AT 20,0;" Press Any Key To Return To Menu": PAUSE 0
 5516 CLS : GO TO 3000
 5518 DATA "What is the diameter of mercury?","miles"
 5519 DATA INT (RND*5000)+4500,INT (RND*10000)+6600,INT (RND*500)+1000,INT (RND*30000)+8000,INT (RND*3000)+17000,3031
 5520 DATA "What is the average distance    Mercury is from the Sun?","miles"
 5521 DATA INT (RND*40000000)+40000000,INT (RND*10000000)+12000000,INT (RND*200000000)+100000000,INT (RND*10000000)+93000000,INT (RND*750000000)+750000000,36000000
 5522 DATA "What is the surface gravity of  Mercury?  (Earth=1)",""
 5523 DATA 1.17,0.90,0.12,0.90+INT (100*(2*RND+.005)/100),0.50+INT (100*(RND+.005))/100,0.38
 5524 DATA "What is the period of orbit for Mercury?","Earth days"
 5525 DATA 100+INT (RND*100+1),INT (RND*40)+10,342.6,232.2,INT (RND*75)+111,88
 5526 DATA "What is the average orbital     speed of Mercury?","km/sec"
 5527 DATA 50+INT (RND*100),INT (RND*12)+2,INT (RND*20)+5.4,INT (RND*5)+5.2,INT (RND*22)+22,48
 5528 DATA "What is the tilt of Mercury's   axis?","degrees"
 5529 DATA 82.1,INT (RND*20)+28.1,INT (RND*10)+11.1,22.2,INT (RND*3)+3.3,0
 5530 DATA "What is Mercury's orbital tilt?","degrees"
 5531 DATA INT (RND*7)+11.1,INT (RND*2)+1.1,0.8,3.9,1.9,7
 5532 DATA "What is the period of rotation  for Mercury?","Earth days"
 5533 DATA .7,INT (RND*100)+100,77.7,22.1,INT (RND*3)+1,59.27
 5534 DATA "How many satellites does Mercuryhave?",""
 5535 DATA 3,INT (RND*8)+4,2,INT (RND*11)+5,1,0
 5536 DATA "What is the coldest temperature extreme on Mercury?","deg. F"
 5537 DATA INT (RND*100)+100,-(INT (RND*10)+10),-155,222,22,-270
 5538 DATA "What is the diameter of Venus?","miles"
 5539 DATA INT (RND*5000)+1500,INT (RND*10000)+8600,INT (RND*500)+2000,INT (RND*30000)+8800,INT (RND*3000)+17000,7521
 5540 DATA "What is the average distance    Venus is from the Sun?","miles"
 5541 DATA INT (RND*40000000)+70000000,INT (RND*10000000)+12000000,INT (RND*200000000)+100000000,INT (RND*10000000)+93000000,INT (RND*750000000)+750000000,67200000
 5542 DATA "What is the surface gravity of  Venus?  (Earth=1)",""
 5543 DATA 1.17,0.20,0.12,1.2+INT (100*(2*RND+.005)/100),1.5+INT (100*(RND+.005))/100,0.90
 5544 DATA "What is the period of orbit for Venus?","Earth days"
 5545 DATA 100+INT (RND*100+1),INT (RND*40)+10,342.6,32.2,INT (RND*75)+111,224.7
 5546 DATA "What is the average orbital     speed of Venus?","km/sec"
 5547 DATA 50+INT (RND*100),INT (RND*12)+2,INT (RND*20)+5.4,INT (RND*5)+5.2,INT (RND*22)+52,35
 5548 DATA "How many satellites does Venus  have?",""
 5549 DATA 2,INT (RND*8)+3,1,INT (RND*11)+5,3,0
 5550 DATA "What is the coldest temperature extreme on Venus?","deg. F"
 5551 DATA INT (RND*100)+100,-INT (RND*10)+100,-115,227,55,-27
 5552 DATA "What is the hottest temperature extreme on Venus?","deg. F"
 5553 DATA INT (RND*100)+200,INT (RND*10)+100,555,217,155,896
 5554 DATA "What is the diameter of Earth?","miles"
 5555 DATA INT (RND*5000)+1500,INT (RND*10000)+8600,INT (RND*500)+2000,INT (RND*30000)+8800,INT (RND*3000)+17000,7927
 5556 DATA "What is the average distance    Earth is from the Sun?","miles"
 5557 DATA 40000000,INT (RND*10000000)+12000000,200000000,INT (RND*10000000)+53000000,INT (RND*750000000)+750000000,93000000
 5558 DATA "What is the average orbital     speed of Earth?","km/sec"
 5559 DATA 50+INT (RND*100),INT (RND*12)+2,INT (RND*20)+5.4,INT (RND*5)+5.2,INT (RND*22)+52,30
 5560 DATA "What is the coldest temperature extreme on Earth?","deg. F"
 5561 DATA INT (RND*10)+2,-(INT (RND*10)+50),-222.1,-11,22,-126.9
 5562 DATA "What is the hottest temperature extreme on Earth?","deg. F"
 5563 DATA INT (RND*100)+200.6,INT (RND*10)+99,110.8,217,155,136.4
 5564 DATA "What is the diameter of Mars?","miles"
 5565 DATA INT (RND*2000)+1500,INT (RND*10000)+8600,INT (RND*500)+7200,INT (RND*3000)+15000,INT (RND*30000)+6000,4197
 5566 DATA "What is the average distance    Mars is from the Sun?","miles"
 5567 DATA INT (RND*10000000)+12000000,200000000,99000000,INT (RND*10000000)+53000000,INT (RND*750000000)+250000000,141600000
 5568 DATA "What is the average orbital     speed of Mars?","km/sec"
 5569 DATA 50+INT (RND*100),INT (RND*12)+2,INT (RND*20)+15.4,INT (RND*5)+5.2,INT (RND*22)+52,24
 5570 DATA "What is the surface gravity of  Mars?  (Earth=1)",""
 5571 DATA 1.89,1.20,0.52,1.2+INT (100*(2*RND+.005)/100),.5+INT (100*(RND+.005))/100,0.38
 5572 DATA "What is Mars' mass relative to  Earth?   (Earth=1)",""
 5573 DATA INT (RND*100)+80,.059,1.11,INT (RND*5)+1.221,.332,.107
 5574 DATA "What is the period of orbit for Mars?","Earth years"
 5575 DATA INT (RND*100)+5,INT (RND*40)+10,.75,32.2,INT (RND*3)+2.51,1.88
 5576 DATA "How many satellites does Mars   have?",""
 5577 DATA INT (RND*8)+5,1,0,15,3,2
 5578 DATA "What is the coldest temperature extreme on Mars?","deg. F"
 5579 DATA INT (RND*100)+100,-(INT (RND*10)+100),-117,207,65,-190
 5580 DATA "What is the hottest temperature extreme on Mars?","deg. F"
 5581 DATA INT (RND*100)+200,INT (RND*10)+140,355,210,145,80
 5582 DATA "Jupiter",88733,"miles",11.86,"Earth years",9.8,"hours",13,"km/sec.",483600000,"miles"
 5583 DATA "Saturn",74600,"miles",29.46,"Earth years",10.65,"hours",9.7,"km/sec.",886700000,"miles"
 5584 DATA "Uranus",31600,"miles",84.01,"Earth years",15.6,"hours",6.8,"km/sec.",1782000000,"miles"
 5585 DATA "Neptune",30200,"miles",164.8,"Earth years",18.5,"hours",5.4,"km/sec.",2794000000,"miles"
 5586 DATA "Moon","km",3476,"",0.16,"",0.012
 5587 DATA "Sun","km",865000,"",27.8,"",332946
 6000 CLS : PRINT AT 0,0;"PLANET"'"FINDER"
 6010 PRINT AT 0,12;"Facts about the Moon"
 6020 PRINT AT 5,11;"Symbol:"
 6022 PLOT 151,128: DRAW -3,8,-PI: DRAW 3,-8
 6025 PRINT AT 9,0;"________________________________"
 6026 PRINT "Distance from Earth: 384,000 km"
 6027 PRINT "Diameter: 3,476 km"
 6028 PRINT "Revolution around Earth: 27.3 d"'"Rotation: 27d 7h 43m"
 6030 PRINT "Orbital speed: 1.026 km per sec."
 6032 PRINT "Axis tilt: 6.68 degrees"
 6034 PRINT "Mass relative to Earth: 0.012"
 6035 PRINT "Volume relative to Earth: 0.020"
 6036 PRINT "Mean density: 3.36"
 6037 PRINT "Surface gravity: 0.16"
 6040 PRINT AT 21,0;"                                "
 6050 FOR f=1 TO 15: CIRCLE INK 5;24,130,f: NEXT f: PRINT AT 4,5;"q"
 6052 PRINT AT 8,1;"Earth"
 6053 PRINT AT 3,4;"Moon"
 6058 PRINT AT 21,0;"   Press any key to continue    "
 6059 PAUSE 0: FOR f=10 TO 21: PRINT AT f,0;"                                ": NEXT f
 6060 PRINT AT 10,0;"Escape velocity: 5324 m.p.h."
 6070 PRINT "Eccentricity of orbit: 0.055"
 6080 PRINT "Oblateness: 0.0005"
 6085 PRINT : PRINT "              High  107 deg. C"
 6092 PRINT "Temperature } Low  -153 deg. C"
 6095 PRINT "Extremes      High  225 deg. F"
 6096 PRINT "              Low  -243 deg. F"
 6097 PRINT : PRINT "Atmosphere: none"
 6098 PRINT AT 21,0;"   Press any key to continue    "
 6099 PAUSE 0: FOR f=9 TO 21: PRINT AT f,0;"                                ": NEXT f: GO TO 8000
 7000 DATA "36,000,000 miles","57,900,000 km","0.387 AU","88 Earth days","59d 16h 02m","48 km/sec","0 degrees","3,031 miles (4,800 km)","(Earth=1) 0.382","0.055","0.056","5.44 g/cubic cm."
 7010 DATA "0.38","0.206","5.5%","0","                High  350 deg. C","   Low  -170 deg. C","        High  660 deg. F","                Low  -270 deg. F","none","none"
 7020 DATA "67,200,000 miles","108,200,000 km","0.723 AU","224.7 Earth days","243d 0h 14m R","35 km/sec","3 degrees","7,521 miles(12,104 km)","(Earth=1) 0.949","0.815","0.855","5.24 g/cubic cm."
 7022 DATA "0.90","0.007","66%","0","                High  480 deg. C","   Low  -33  deg. C","        High  896 deg. F","                Low  -27  deg. F","none","CO2"
 7030 DATA "93,000,000 miles","149,600,000 km","1.000 AU","365.26 Earth days"," 23h 56m 04s","30 km/sec","23.45 degrees","7,927 miles(12,756 km)","(Earth=1) 1.000","1.000","1.000","5.52 g/cubic cm."
 7032 DATA "1.00","0.017","39%","0.003","              High  58    deg. C"," Low  -88.3  deg. C","      High  136.4 deg. F","              Low  -126.9 deg. F","1","N2                              O2"
 7040 DATA "141,600,000 miles","227,800,000 km","1.524 AU","1.88 Earth years"," 24h 37m 12s","24 km/sec","25.2 degrees","4,197 miles (6,794 km)","(Earth=1) 0.5326","0.107","0.151","3.93 g/cubic cm."
 7042 DATA "0.38","0.093","15%","0.009","                High  27  deg. C","   Low  -123 deg. C","        High  80  deg. F","                Low  -190 deg. F","2","CO2"
 7050 DATA "483,600,000 miles","778,300,000 km","5.203 AU","11.86 Earth years","9h 48m 48s E","13 km/sec","3.1 degrees","88,733 mls. 142,796 km","(Earth=1) 11.19","317.9","1,403","1.33 g/cubic cm."
 7052 DATA "2.87","0.048","44%","0.063","              High 29,700 deg. C"," Low -95     deg. C","      High 53,500 deg. F","              Low -140    deg. F","16(plus rings)","H2                              He"
 7060 DATA "886,700,000 miles","1,427,000,000 km","9.539 AU","29.46 Earth years","10h 39m 24s E","9.7km/sec","26.7 degrees","74,600 mls. 120,000 km","(Earth=1) 9.41","95.17","833","0.70 g/cubic cm."
 7062 DATA "1.32","0.056","42%","0.109","                High     -","   Low  -180 deg. C","        High     -","                Low  -292 deg. F","23?,plus rings","H2                              He"
 7070 DATA "1,782,000,000 miles","2,869,000,000 km","19.18 AU","84.01 Earth years","15h 36m ?R","6.8km/sec","82.1 degrees","31,600 miles;50,800 km","(Earth=1) 3.98","14.56","63.0","1.28 g/cubic cm."
 7072 DATA "0.93","0.047","45%","0.063","                High     -","   Low  -210 deg. C","        High     -","                Low  -346 deg. F","5 (plus rings)","H2                              He"
 7080 DATA "2,794,000,000 miles","4,497,000,000 km","30.06 AU","164.8 Earth years","18h 30m ?","5.4km/sec","28.8 degrees","30,200 miles;48,600 km","(Earth=1) 3.81","17.24","55.3","1.75 g/cubic cm."
 7082 DATA "1.23","0.009","52%","0.026","                High     -","   Low  -220 deg. C","        High     -","                Low  -364 deg. F","2","H2                              He"
 7090 DATA "3,666,000,000 miles","5,900,000,000 km","39.44 AU","247.7 Earth years","6d 9h 23m","4.7km/sec","60? degrees","1,900? miles;3,000? km","(Earth=1) 0.24?",".002?",".013?","0.7? g/cubic cm."
 7092 DATA ".03?","0.250","?","?","               High -230  deg. C","  Low  -234? deg. C","       High -382  deg. F","               Low  -390? deg. F","1","none"
 8000 PRINT AT 7,10;"Lunar Phases"
 8002 FOR f=1 TO 7: CIRCLE INK 5;122,52,f: NEXT f
 8020 PRINT AT 15,10;"q"
 8021 PRINT AT 15,20;"q"
 8022 PRINT AT 20,15;"q"
 8023 PRINT AT 10,15;"q"
 8025 PRINT AT 12,11;"q"
 8027 PRINT AT 12,19;"q"
 8028 PRINT AT 18,19;"q"
 8029 PRINT AT 18,11;"q"
 8030 PRINT AT 9,10;"1st quarter"
 8031 PRINT AT 21,10;"Last quarter"
 8032 PRINT AT 12,4;"Waxing"'"   gibbous"
 8035 PRINT AT 12,21;"Waxing";AT 13,21;"crescent"
 8040 PRINT AT 15,5;"Full"
 8042 PRINT AT 15,22;"New"
 8048 PRINT AT 17,21;"Waning";AT 18,21;"crescent"
 9045 PRINT AT 17,4;"Waning"'"   gibbous"
 9046 FOR f=10 TO 20 STEP 2: PRINT AT f,29;"<--": NEXT f
 9050 PRINT AT 2,21;" Press Any "
 9052 PRINT AT 3,21;"   Key To  "
 9053 PRINT AT 4,21;"   Return  "
 9054 PRINT AT 5,21;"  To Menu  "
 9055 PAUSE 0
 9056 CLS : GO TO 3000
 9060 CLS : PRINT AT 0,0;"PLANET"'"FINDER"
 9062 PRINT AT 0,15;"Weight Simulation"
 9070 FOR f=17 TO 18: PRINT AT f,4;"                       ": NEXT f
 9072 FOR f=13 TO 16: PRINT AT f,13;"    ": NEXT f
 9073 PRINT AT 12,6;"..::::........................::::.."
 9074 FOR f=9 TO 11: PRINT AT f,7;"  ";AT f,21;"  ": NEXT f
 9075 PRINT AT 8,4;"________      ________"
 9080 INPUT "Input Planetary number ";pl
 9081 IF pl<0 OR pl>11 THEN GO TO 9080
 9082 INPUT "Input weight on Earth ";we
 9083 IF we<0 THEN GO TO 9082
 9084 RESTORE 2069+pl: READ o$
 9085 PRINT AT 5,4;"Weight on Earth:";we
 9093 READ q
 9094 PRINT AT 6,4;"Weight on ";o$;":";q*we
 9995 PRINT AT 21,0;"Do you wish to continue ? (y/n)"
 9996 IF INKEY$="y" THEN CLS : GO TO 9060
 9997 IF INKEY$="n" THEN CLS : GO TO 3000
 9998 GO TO 9996

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.

Tags

Downloadable TS 2068 Astronomy