Tasword NLQ Loader (tasnlq.Bb)

Developer(s): Bob Mitchell
Date: 1992
Type: Program
Platform(s): TS 2068
Tags: Printer

Makes a Fastext 80 imitate near-letter-quality print: it loads a Tasword .CT file from a chosen line and prints each 64-character line twice, the first time without a line feed. A 16-byte machine-code routine, POKEd into the REM at line 10, clears the text buffer first; line 170 can switch in the UK font, and line 1000 is a debugging aid.

Listing only: it loads the file from disk and prints through the Larken printer channel and driver POKEs, and uses the LKDOS ON ERR.

Published in Sinc-Link January-February 1992 (Bob’s Notebook: Near Letter Quality Printing).

Related Articles

Routine to print at near letter quality on the Smith-Corona Fastext 80, an 8-pin dot matrix printer. Requires Larken Extended BASIC.

Source Code

  10 REM xxxxxxxxxxxxxxxx  (16 x's)
  12 RANDOMIZE USR 100: OPEN # 3,"lp"
  15 LET prog=PEEK 23635+256*PEEK 23636: LET prog=prog+5
  20 RESTORE 50
  30 FOR i=1 TO 16: READ v: POKE prog+i-1,v: NEXT i
  50 DATA 33,0,130,1,0,126,62,32,119,35,11,120,177,32,247,201
  60 REM ***********************
 100 REM Tasword Special Loader to simulate NLQ Copy in Pica.
 110 REM Use Single Sheet Paper.
 120 REM Line 170 will switch in UK font if REM removed.
 124 REM If the last line on a page does not double print press the On-line switch once.
 126 REM When continuous line feeds occur, use BREAK to STOP action.
 130 REM **********************
 140 RANDOMIZE USR prog
 150 RANDOMIZE USR 100: POKE 16090,69
 160 GO SUB 270
 170 REM GO SUB 250: LPRINT CHR$ 27;CHR$ 82;CHR$ 2: GO SUB 260
 175 POKE 23658,0: CLS
 180 GO SUB 280: RANDOMIZE USR 100: LOAD n$+".CT"CODE
 185 DIM a$(65): LET j=1
 187 INPUT "start line # ? ";sl: LET sl=sl-1: LET a=sl*64+33280
 188 PRINT #0;"BREAK=STOP"
 190 ON ERR GO TO 400: FOR i=a TO 53000
 200 IF PEEK i<32 OR PEEK i>122 THEN LET a$(j)=CHR$ 32: LET j=j+1: GO TO 230
 210 LET a$(j)=CHR$ PEEK i: LET j=j+1
 220 IF j>64 THEN RANDOMIZE USR 100: POKE 16092,0: LPRINT a$: RANDOMIZE USR 100: POKE 16092,10: LPRINT a$: LET j=1: DIM a$(65)
 230 NEXT i
 240 STOP
 250 RANDOMIZE USR 100: POKE 16093,32: RETURN
 260 RANDOMIZE USR 100: POKE 16093,0: GO SUB 270: RETURN
 270 RANDOMIZE USR 100: POKE 16094,10: LPRINT : RETURN
 280 INPUT "Tasword file name (<=6) "; LINE n$: GO SUB 290: RETURN
 290 INPUT "drv? ";drv: RANDOMIZE USR 100: GO TO drv: RETURN
 400 ON ERR RESET: INPUT "1=more 0=quit ";mq: IF mq THEN RANDOMIZE USR prog: GO TO 180
 410 GO SUB 290: RANDOMIZE USR 100: NEW
 490 STOP
 500 GO SUB 290 : RANDOMIZE USR 100: SAVE "tasnlq.Bb" LINE 10
 510 STOP
 999 REM test line follows:
1000 FOR i=33280 TO 34000: PRINT i,PEEK i;TAB 22;CHR$ PEEK i: NEXT i

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.