2068 Word Images

Author(s): Thomas B. Woods
Publication: SyncWare News
Pub Details: SyncWare News v2 n4 (Volume 2, Issue 4)
Date: Mar-Apr 1985
Pages: 13-14

One particularly strong fascination the computer holds over me is its almost magical ability to conjure up powerful images in my mind. I’m not talking about the dazzling graphic TV images of an arcade game. These are nice, but far stronger are the pictures YOU create in YOUR mind in response to written words.

Have you ever read a good book that simply swept you away to some other time and place? Skilled writers know the power that words and language hold. With a few strokes of their mighty pens they wield enormous influence. Writers can cast their spells and wrap us around their little fingers. This magic comes from the words they use.

Surprisingly, most readers are unaware (and many will deny vehemently) that simple words can control our thoughts and consequently our behavior. The subtle nature of this mind control technique stems from our own imaginations. Whenever we look at written words, all we ever really see are symbols printed on paper. It is our minds which attach meaning and significance to the symbols.

Anyone, in possession of a daedal touch, may slip into your head at will! You can use the computer to illustrate this phenomenon by programming it to choose and print words on the TV screen. By consciously thinking about the images your mind creates in response you’ll soon realize the powerful spell that words hold over you.

Enter this listing and RUN it. The program gives you the choice of determining your own sentence structure or letting the computer do it for you. The word types you can choose are 1. nouns, 2. verbs, 3. adjectives, 4. adverbs, and 5. prepositional phrases. To create a sentence consisting of an adjective, a noun, a verb, and finally a prepositional phrase, you would enter the command “3/1/2/5” when lines 60-100 ask you to input the sentence structure you wish. Remember to use the diagonal slash (/) between each number. Instead of entering a command at this point, you can also press just ENTER. This tells the computer to make a selection for you. It will randomly choose a structure from those programmed into lines 8000 to 8007.

Once the structure is finally decided upon, the computer forms sentences by taking the appropriate words from the DATA statements in lines 9000-9050. You can experiment with your own words by plugging them into these lines. Note, however, that this listing will READ only the first 20 words given in each DATA line. This is done by line 1015 which you can alter to suit your needs.

You can stop the generation of sentences to create a new structure by holding your finger on the space bar until the Selection menu comes up on the TV.

  10 REM * WORD IMAGES *"
15 LET S$=""
18 LET NOUN=9000
20 LET VERB=9010
22 LET ADJECTIVE=9020
24 LET ADVERB=9030
26 LET PREP=9040
28 LET OBJECT=9050
30 LET P=0
60 PRINT AT 3,7;"*** WORD IMAGES ***"
70 PRINT : PRINT "Select the sentence order you want to produce. EXAMPLE:"
80 PRINT : PRINT "3/1/2/4 (ENTER)": PRINT "prints a sentence order of ADJECTIVE, NOUN, VERB, ADVERB"
90 PRINT : PRINT TAB 1;"1-NOUN";TAB 1;"2-VERB";TAB 1;"3-ADJECTIVE";TAB 1;"4-ADVERB";TAB 1;"5-PREPOSITION"
95 PRINT AT 20,0;"Press ENTER for computer selections"
100 INPUT A$
102 IF A$="" THEN GO TO 8000
105 CLS
110 REM Set-up
115 RANDOMIZE
117 LET C=1
120 FOR X=C TO LEN A$: IF A$(X)<>"5" THEN NEXT X: GO TO 125
122 LET A$=A$( TO X)+"/6"+A$(X+1 TO ): LET C=X+4: GO TO 120
125 FOR X=1 TO LEN A$
130 IF A$(X)="/" THEN NEXT X
140 IF A$(X)="1" OR A$(X)="2" OR A$(X)="3" OR A$(X)="4" OR A$(X)="5" OR A$(X)="6" THEN GO SUB 1000*VAL A$(X)
145 NEXT X
200 REM print sentence
202 PAUSE 300: CLS
205 FOR X=1 TO LEN S$
210 IF S$(X)=" " THEN PRINT
215 PRINT S$(X);
220 NEXT X
225 IF INKEY$=" " THEN RUN
230 LET S$="": IF P=0 THEN GO TO 125
235 GO TO 8001+INT (RND*7)
1000 REM noun
1010 RESTORE NOUN
1015 FOR Y=1 TO 20
1020 READ W$: IF INT (RND*10)=3 THEN LET S$=S$+" "+W$: RETURN
1025 NEXT Y
1030 GO TO 1001*VAL A$(X)
2000 REM verb
2010 RESTORE VERB
2020 GO TO 1015
3000 REM adjective
3010 RESTORE ADJECTIVE
3020 GO TO 1015
4000 REM adverb
4010 RESTORE ADVERB
4020 GO TO 1015
5000 REM preposition
5010 RESTORE PREP
5020 GO TO 1015
6000 LET S$=S$+" THE"
6010 RESTORE OBJECT
6020 GO TO 1015
8000 LET P=1
8001 LET A$="1/2/1/5/6": GO TO 125
8002 LET A$="3/1/5/6/4/2/1/5/6": GO TO 125
8003 LET A$="3/1/2/4": GO TO 125
8004 LET A$="1/2": GO TO 125
8005 LET A$="1/5/6/2/1": GO TO 125
8006 LET A$="1/5/6/2/4": GO TO 125
8007 LET A$="3/1/4/2/1/5/6": GO TO 125
9000 DATA "CHILDREN","PEOPLE","WORKERS","WARRIORS","WITCHES","LOVERS","BOYS","GIRLS","DOCTORS","BUTCHERS","PROGRAMMERS","ZOMBIES","MAGICIANS","TRUCKERS","ACTORS","POLITICIANS","MANIACS","PRIESTS","SAGES","ANALYSTS"
9010 DATA "ENCOURAGE","PLUNDER","ATTRACT","WOO","CARESS","TOUCH","WATCH","INSPIRE","BRAINWASH","AMUSE","EVADE","FIGHT","SEDUCE","INSULT","BITE","EAT","PECK","ATTACK","EMULATE","HONOR"
9020 DATA "BIG","SMALL","SWEET","SOUR","PASSIONATE","SILENT","LOUD","INTIMATE","FAT","SKINNY","SAD","JOYOUS","HUNGRY","THIRSTY","SATISFIED","GREEDY","GENEROUS","PEACEFUL","RAGING","STUFFED"
9030 DATA "QUESTIONINGLY","SELFISHLY","FEARSOMELY","BRAVELY","AUTHORITATIVELY","CARELESSLY","CAREFULLY","CONFIDENTLY","HALFHEARTEDLY","ENTHUSIASTICALLY","STUPIDLY","COLDLY","WARMLY","THOUGHTFULLY","MADLY","BLISSFULLY","GRUDGINGLY","QUICKLY","SLOWLY","WISELY"
9040 DATA "IN","ABOUT","AROUND","FROM","CLEANING","LEAVING","BENEATH","ABOVE","PACING","WATCHING","BESIDE","NEAR","AT","WRECKING","BEHIND","ABOUT","ACROSS","ALONG","WITHIN","CRITICIZING"
9050 DATA "HOUSE","OFFICE","STREET","SEWER","YARD","TUNNEL","CASTLE","MAZE","DESERT","SWAMP","FORT","FOREST","HIDEOUT","CITY","BEDROOM","COFFIN","OUTHOUSE","PENTHOUSE","CAVE","GRAVEYARD"

Line 225 scans the keyboard after each sentence is printed. If you’re pressing the SPACE when this line is executed, then the computer will return to the start. Otherwise. a new sentence will be generated.

I guarantee that the sentences this program builts will trigger your imagination to produce all sorts of pictures and feelings. They’ll range from philosophical universal truths to raunchy raw unexpurgated obscenity. If you become upset by what you see on the screen, don’t blame me. Remember, the computer only prints symbols. It’s YOUR imagination that’s doing the dirty work.

I sat entranced for quite some time after I wrote this image maker. Some of the program’s results were so suggestive that I dare not expose them in SyncWare News, a journal of such high moral character. But some of the others I particularly liked were, “Workers woo people in the sewer”, “Truckers in the street quickly brainwash people in the office”, and best of all, “Workers beneath the outhouse watch carefully”. I don’t want to spoil all the fun so I won’t tell you any more. Just sit back, let WORD IMAGES cast its spell, and let your imagination soar! (What’s a daedal look like?-ed.)

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.