Shifting Squares

Date: 1987
Type: Diskette
Platform(s): QL
Tags: Demo

A 3×3 sliding-tile puzzle that the QL plays by itself. The board of tiles 1 to 9 (9 is the space) is shuffled with 25 to 34 random moves, then the computer keeps making random legal moves, printing the board after each one, until the tiles are back in order, and reports how many moves it took.

The legal moves for each position of the space are held in DATA. With purely random moves a solution can take a very long time. No author or source is printed; it appeared in the QL Shorts column with short programs by Rob Miles and D Duncan.

Published in Sinc-Link July-August 1987 (QL Shorts).

Related Articles

Sound Experimenter and Easel Print for the QL.

Source Code

12   WINDOW 452,236,60,20
14   MODE 8
20   init
30   print_board
40   set_shuffle
50   find_space
60   REPeat game
70    win_pos
80    IF S%=0 THEN EXIT game
90    rnd_mve
100   do_move
110   MOVE%=MOVE%+1
120   print_board
130  END REPeat game
140  PRINT "SOLVED IN ";MOVE%
1000 DEFine PROCedure init
1010 DIM B%(9)
1020 DIM M$(9,4)
1030 DIM M%(9)
1040 Q%=0
1050 DATA "24  ","135 ","26  ","157 ","2468"
1060 DATA "359 ","48  ","579 ","68  "
1070 DATA 2,3,2,3,4,3,2,3,2
1080 RESTORE 1050
1090 FOR I=1 TO 9
1100  READ M$(I)
1110 END FOR I
1120 FOR I=1 TO 9
1130  READ M%(I)
1140 END FOR I
1150 MOVE%=0
1499 END DEFine init
1500 DEFine PROCedure print_board
1510 FOR I=1 TO 9
1520  PRINT B%(I);" ";
1530  IF I=INT(I/3)*3 THEN PRINT
1540 END FOR I
1550 PRINT
1560 pause_1
1999 END DEFine print_board
2000 DEFine PROCedure set_shuffle
2010 FOR I=1 TO 9
2020  B%(I)=I
2030 END FOR I
2040 P%=9
2050 N%=RND(25 TO 34)
2060 FOR Z=1 TO N%
2070  rnd_mve
2080  do_move
2090 END FOR Z
2100 Q%=0
2999 END DEFine set_shuffle
3000 DEFine PROCedure find_space
3010 FOR I=1 TO 9
3020  IF B%(I)=9 THEN P%=I
3030 END FOR I
3999 END DEFine find_space
4000 DEFine PROCedure win_pos
4010 S%=0
4020 FOR I=1 TO 9
4030  IF I<>B%(I) THEN S%=1
4040 END FOR I
4999 END DEFine win_pos
5000 DEFine PROCedure pause_1
5010 FOR I=1 TO 500
5020 END FOR I
5999 END DEFine pause_1
6000 DEFine PROCedure rnd_mve
6010 I%=RND(1 TO M%(P%))
6020 J%=M$(P%,I%)
6999 END DEFine rnd_mve
7000 DEFine PROCedure do_move
7010 T%=B%(P%)
7020 B%(P%)=B%(J%)
7030 B%(J%)=T%
7040 Q%=P%
7050 P%=J%
7999 END DEFine do_move

Note: Type-in program listings on this website use ZMAKEBAS notation for graphics characters.