Financial Program

Source Code

    3 GO TO 17
    5 CLS :REM   PLOTTER V9 N11 \{20}\{1} BY DICK WAGNER. MODULES ARE     PROGRAMS FROM THE BOOK          "80 PRACTICAL TIME SAVING         PROGRAMS FOR THE TRS-80" BY    CHARLES J. CARROLL. SOME HAVE   BEEN MODIFIED AND THE SINGLE    PROGRAM HAS BEEN MADE TO        COMBINE THE MODULES.          \{20}\{0}
   10 PRINT AT 3,0;"FINANCIAL CALCULATIONS FOR :    LOANS, SAVINGS, AND             COMPOUND INTEREST"''
   15 PRINT AT 9,0;"VARIABLES ARE:                    INITIAL DEPOSIT         (A)     INTEREST RATE           (I)     FUTURE VALUE            (V)     NUMBER OF YEARS         (T)     NUMBER OF TIMES/YEAR            PRINCIPLE IS COMPOUNDED (TY)"
   16 PAUSE 0
   17 CLS 
   20 PRINT " 1 COMPOUND INTEREST"
   25 PRINT '" 2 COMPOUND INTEREST  TO ACHIEVE    DESIRED AMOUNT"
   30 PRINT '" 3 RATE OF RETURN IN % PER YEAR"
   35 PRINT '" 4 FUTURE VALUE"
   40 PRINT '" 5 MONTHLY PAYMENT TO OBTAIN       DESIRED AMOUNT"
   45 PRINT '" 6 MONTHLY PAYMENTS FOR AMOUNT      TO BE FINANCED"
   50 PRINT '" 7 MONTHLY LOAN PAYMENT"
   55 PRINT '" 8 LOAN BALANCE AT END OF ANY      BLOCK OF PAYMENT PERIODS"
   60 PRINT '" 9 AFFORDABLE LOAN AMOUNT"
   65 PRINT '"10 SINKING FUND"
   70 INPUT "FINANCIAL CALCULATION DESIRED?         ";X
   72 IF X=0 THEN GO TO 9998
   73 IF X=11 THEN GO TO 9990
   74 IF X<1 OR X>11 THEN GO TO 10
   75 GO TO X*100+10+100*(X>9)
   80 STOP 
  100 REM \{20}\{1}COMPOUND INTEREST\{20}\{0}
  110 CLS 
  120 INPUT "AMOUNT TO BE COMPOUNDED? ";A
  130 INPUT "INTEREST RATE IN %? ";I:LET I=I/100
  140 INPUT "NUMBER OF YEARS MONEY IS TO COMPOUND? ";T
  150 INPUT "NUMBER OF COMPOUND PERIODS/YEAR? ";TY
  160 LET V=A*(1+I/TY)^(TY*T)
  170 PRINT "$"; INT (V*100+.5)/100;" COMPOUND INTEREST FOR ";T;" YEARS"
  180 PAUSE 0:RUN 
  200 REM \{20}\{1}COMPOUND INTEREST\{20}\{0}
  210 CLS 
  220 INPUT "AMOUNT TO BE COMPOUNDED? ";A
  230 INPUT "INTEREST RATE? ";I:LET I=I/100
  240 INPUT "FINAL DESIRED AMOUNT? ";V
  250 INPUT "NUMBER OF COMPOUND PERIODS/YEAR? ";TY
  260 LET T= LN (V/A)/(LN (1+I/TY)*TY)
  270 PRINT "COMPOUND ";TY;" TIMES PER YEAR WILL REQUIRE THE MONEY TO BE DEPOSITED "; INT (T*10+.5)/10;" YEARS"
  280 PAUSE 0:RUN 
  300 REM \{20}\{1}RATE OF RETURN\{20}\{0}
  310 CLS 
  320 INPUT "AMOUNT TO BE COMPOUNDED? ";A
  330 INPUT "FINAL AMOUNT? ";V
  340 INPUT "NUMBER OF YEARS MONEY IS TO COMPOUND? ";T
  350 INPUT "NUMBER OF COMPOUND PERIODS/YEAR? ";TY
  360 LET I=((V/A)^(1/(TY*T))-1)*TY
  370 PRINT "RATE OF RETURN IS ";I*100;"% PER YEAR"
  380 PAUSE 0:RUN 
  400 REM \{20}\{1}FUTURE VALUE\{20}\{0}
  410 CLS 
  420 INPUT "AMOUNT OF MONTHLY PAYMENT? ";A
  430 INPUT "INTEREST RATE IN %? ";I:LET I=I/1200
  440 INPUT "NUMBER OF YEARS? ";T:LET T=T*12
  450 LET FV=A/I*((1+I)^(T+1)-(1+I))
  460 PRINT "$"; INT (FV*100+.5)/100
  470 PAUSE 0:RUN 
  500 REM \{20}\{1}PATMENTFOR AMOUNT\{20}\{0}
  510 CLS 
  520 INPUT "FINAL DESIRED AMOUNT? ";FV
  530 INPUT "INTEREST RATE IN %? ";I:LET I=I/1200
  540 INPUT "NUMBER OF YEARS? ";T:LET T=T*12
  550 LET A=(FV*I)/((1-I)^(T+1)-(1+I))
  560 PRINT "$"; INT (A*100+.5)/100;" MONTHLY PAYMENTS"
  570 PAUSE 0:RUN 
  600 REM \{20}\{1}NUMBER OF PAYMENTS\{20}\{0}
  610 CLS 
  620 INPUT "AMOUNT TO BE FINANCED? ";P
  630 INPUT "INTEREST RATE IN %? ";I:LET I=I/1200
  640 INPUT "AMOUNT OF AFFORDABLE MONTHLY    PAYMENT? ";A
  650 LET N= LN (A/(A-P*I))/ LN (1+I)
  660 PRINT N;" MONTHLY PAYMENTS"
  670 PAUSE 0:RUN 
  700 REM \{20}\{1}MONTHLY LOAN PAYMENT\{20}\{0}
  710 CLS 
  720 INPUT "AMOUNT TO BE FINANCED? ";P
  730 INPUT "INTEREST RATE IN %? ";I:LET I=I/1200
  740 INPUT "NUMBER OF YEARS OF FINANCING? ";N:LET N=N*12
  750 LET A=P*(I/12)/(1-(1+I/12)^-N)
  760 PRINT "MONTHLY PAYMENT IS $"; INT (A*100+.5)/100
  770 PAUSE 0:RUN 
  800 REM \{20}\{1}LOAD BALANCE\{20}\{0}
  810 CLS :INPUT "AMOUNT TO BE FINANCED? ";P
  820 INPUT "INTEREST RATE IN %? ";I:LET I=I/1200
  830 INPUT "MONTHLY PAYMENT? ";A
  840 INPUT "BEGINNING PAYMENT NUMBER? ";X
  850 INPUT "ENDING PAYMENT NUMBER? ";Y
  860 LET B=1/((I+1)^-Y)*((A*(((1+I)^-Y)-1))/I+P)
  870 PRINT "BALANCE AT THE END OF PAYMENT   NUMBER ";Y;"--$"; INT (B*100+.5)/100
  880 LET AI=B-(1/((I+1)^-(X-1))*((A*(((1+I)^-(X-1))-1))/I+P))+(Y-X+1)*A
  890 PRINT "ACCUMULATED INTEREST AT THE END OF PAYMENT NUMBER ";Y;"--$"; INT (AI*100+.5)/100
  895 PAUSE 0:RUN 
 1000 REM \{20}\{1}LOAN AMOUNT\{20}\{0}
 1005 CLS 
 1010 INPUT "NUMBER OF PAYMENTS DESIRED? ";N
 1020 INPUT "INTEREST RATE IN %? ";I:LET I=I/1200
 1030 INPUT "AMOUNT MONTHLY PAYMENT? ";A
 1040 LET P=A*(1-(1+I)^-N)/I
 1050 PRINT "YOU CAN AFFORD TO BORROW $";P
 1060 PAUSE 0:RUN 
 1100 REM \{20}\{1}SINKING FUND\{20}\{0}
 1110 CLS 
 1120 INPUT "AMOUNT TO BE ACCUMULATED? ";P
 1130 INPUT "INTEREST RATE IN %? ";I:LET I=I/100
 1140 INPUT "NUMBER OF YEARS OF ACCUMULATION? ";N
 1150 LET A=P*I/(((1+I)^N)-1)
 1160 PRINT "YEARLY DEPOSIT IS $"; INT (A*100+.5)/100
 1170 PAUSE 0:RUN 
 3800 PAUSE 0:RUN 
 9989 STOP